Merge lp:~fginther/dee/add-code-coverage into lp:dee

[Francis Ginther]

Add code coverage reporting with coverage-html and coverage-gcovr targets.

Coverage reporting can be enabled with --enable-gcov.

Add code coverage reporting with coverage-html and coverage-gcovr targets.

Coverage reporting can be enabled with --enable-gcov.

Testing:
 - Built coverage targets and verified results.
 - Built in pbuilder chroot with hooks to enable gcovr report.

[PS Jenkins bot (ps-jenkins)]

PASSED: Continuous integration, rev:395
http://jenkins.qa.ubuntu.com/job/dee-mbs-ci/3/
Executed test runs:
    SUCCESS: http://jenkins.qa.ubuntu.com/job/dee-mbs-ci/./build=pbuilder,distribution=quantal,flavor=amd64/3/console
    SUCCESS: http://jenkins.qa.ubuntu.com/job/dee-mbs-ci/./build=pbuilder,distribution=quantal,flavor=i386/3/console

Click here to trigger a rebuild:
http://jenkins.qa.ubuntu.com/job/dee-mbs-ci/3//rebuild/?

review: Approve (continuous-integration)

[lp:~fginther/dee/add-code-coverage]

396. By Francis Ginther on 2012-12-13

Fixed building for non-srcdir builds and cleaned up a warning message.

[PS Jenkins bot (ps-jenkins)]

PASSED: Continuous integration, rev:396
http://jenkins.qa.ubuntu.com/job/dee-mbs-ci/4/
Executed test runs:
    SUCCESS: http://jenkins.qa.ubuntu.com/job/dee-mbs-ci/./build=pbuilder,distribution=quantal,flavor=amd64/4/console
    SUCCESS: http://jenkins.qa.ubuntu.com/job/dee-mbs-ci/./build=pbuilder,distribution=quantal,flavor=i386/4/console

Click here to trigger a rebuild:
http://jenkins.qa.ubuntu.com/job/dee-mbs-ci/4//rebuild/?

review: Approve (continuous-integration)

[Francis Ginther (fginther)]

I've fixed the issues with non-srcdir builds:

# mkdir builddir;cd builddir; ../autogen.sh; make

Retested with local builds, pbuilder and jenkins (the -ci run above includes coverage data).

[Michal Hruby (mhr3)]

Seems to work fine now (minus some warnings about double PHONY declaration)

review: Approve

=== modified file 'Makefile.am'
--- Makefile.am	2012-08-10 10:56:44 +0000
+++ Makefile.am	2012-12-13 21:16:19 +0000
@@ -1,3 +1,7 @@
+ACLOCAL_AMFLAGS = -I build/autotools
+
+include $(top_srcdir)/Makefile.am.coverage
+
 SUBDIRS = build src doc examples tools vapi bindings
 
 pkgconfigdir = $(libdir)/pkgconfig
 
=== added file 'Makefile.am.coverage'
--- Makefile.am.coverage	1970-01-01 00:00:00 +0000
+++ Makefile.am.coverage	2012-12-13 21:16:19 +0000
@@ -0,0 +1,48 @@
+
+# Coverage targets
+
+.PHONY: clean-gcno clean-gcda \
+	coverage-html generate-coverage-html clean-coverage-html \
+	coverage-gcovr generate-coverage-gcovr clean-coverage-gcovr
+
+clean-local: clean-gcno clean-coverage-html clean-coverage-gcovr
+
+if HAVE_GCOV
+
+clean-gcno:
+	@echo Removing old coverage instrumentation
+	-find -name '*.gcno' -print | xargs -r rm
+
+clean-gcda:
+	@echo Removing old coverage results
+	-find -name '*.gcda' -print | xargs -r rm
+  
+coverage-html:
+	-$(MAKE) $(AM_MAKEFLAGS) -k check
+	$(MAKE) $(AM_MAKEFLAGS) generate-coverage-html
+  
+generate-coverage-html:
+	@echo Collecting coverage data
+	$(LCOV) --directory $(top_builddir) --capture --output-file coverage.info --no-checksum --compat-libtool
+	LANG=C $(GENHTML) --prefix $(top_builddir) --output-directory coveragereport --title "Code Coverage" --legend --show-details coverage.info
+  
+clean-coverage-html: clean-gcda
+	-$(LCOV) --directory $(top_builddir) -z
+	-rm -rf coverage.info coveragereport
+
+if HAVE_GCOVR
+
+coverage-gcovr:
+	-$(MAKE) $(AM_MAKEFLAGS) -k check
+	$(MAKE) $(AM_MAKEFLAGS) generate-coverage-gcovr
+	
+generate-coverage-gcovr:
+	@echo Generating coverage GCOVR report
+	$(GCOVR) --xml -r $(top_builddir) -o $(top_builddir)/coverage.xml
+	
+clean-coverage-gcovr: clean-gcda
+	-rm -rf $(top_builddir)/coverage.xml
+
+endif # HAVE_GCOVR
+
+endif # HAVE_GCOV
 
=== added file 'build/autotools/gcov.m4'
--- build/autotools/gcov.m4	1970-01-01 00:00:00 +0000
+++ build/autotools/gcov.m4	2012-12-13 21:16:19 +0000
@@ -0,0 +1,89 @@
+# Checks for existence of coverage tools:
+#  * gcov
+#  * lcov
+#  * genhtml
+#  * gcovr
+# 
+# Sets ac_cv_check_gcov to yes if tooling is present
+# and reports the executables to the variables LCOV, GCOVR and GENHTML.
+AC_DEFUN([AC_TDD_GCOV],
+[
+  AC_ARG_ENABLE(gcov,
+  AS_HELP_STRING([--enable-gcov],
+		 [enable coverage testing with gcov]),
+  [use_gcov=$enableval], [use_gcov=no])
+
+  AM_CONDITIONAL(HAVE_GCOV, test "x$use_gcov" = "xyes")
+
+  if test "x$use_gcov" = "xyes"; then
+  # we need gcc:
+  if test "$GCC" != "yes"; then
+    AC_MSG_ERROR([GCC is required for --enable-gcov])
+  fi
+
+  # Check if ccache is being used
+  AC_CHECK_PROG(SHTOOL, shtool, shtool)
+  if test "$SHTOOL"; then
+    AS_CASE([`$SHTOOL path $CC`],
+                [*ccache*], [gcc_ccache=yes],
+                [gcc_ccache=no])
+  fi
+
+  if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
+    AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
+  fi
+
+  lcov_version_list="1.6 1.7 1.8 1.9"
+  AC_CHECK_PROG(LCOV, lcov, lcov)
+  AC_CHECK_PROG(GENHTML, genhtml, genhtml)
+
+  if test "$LCOV"; then
+    AC_CACHE_CHECK([for lcov version], glib_cv_lcov_version, [
+      glib_cv_lcov_version=invalid
+      lcov_version=`$LCOV -v 2>/dev/null | $SED -e 's/^.* //'`
+      for lcov_check_version in $lcov_version_list; do
+        if test "$lcov_version" = "$lcov_check_version"; then
+          glib_cv_lcov_version="$lcov_check_version (ok)"
+        fi
+      done
+    ])
+  else
+    lcov_msg="To enable code coverage reporting you must have one of the following lcov versions installed: $lcov_version_list"
+    AC_MSG_ERROR([$lcov_msg])
+  fi
+
+  case $glib_cv_lcov_version in
+    ""|invalid[)]
+      lcov_msg="You must have one of the following versions of lcov: $lcov_version_list (found: $lcov_version)."
+      AC_MSG_ERROR([$lcov_msg])
+      LCOV="exit 0;"
+      ;;
+  esac
+
+  if test -z "$GENHTML"; then
+    AC_MSG_ERROR([Could not find genhtml from the lcov package])
+  fi
+
+  ac_cv_check_gcov=yes
+  ac_cv_check_lcov=yes
+
+  # Remove all optimization flags from CFLAGS
+  changequote({,})
+  CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
+  changequote([,])
+
+  # Add the special gcc flags
+  COVERAGE_CFLAGS="-O0 --coverage"
+  COVERAGE_CXXFLAGS="-O0 --coverage"
+  COVERAGE_LDFLAGS="-lgcov"
+
+  # Check availability of gcovr
+  AC_CHECK_PROG(GCOVR, gcovr, gcovr)
+  if test -z "$GCOVR"; then
+    ac_cv_check_gcovr=no
+  else
+    ac_cv_check_gcovr=yes
+  fi
+fi
+]) # AC_TDD_GCOV
+
 
=== modified file 'configure.ac'
--- configure.ac	2012-11-28 08:53:48 +0000
+++ configure.ac	2012-12-13 21:16:19 +0000
@@ -140,6 +140,16 @@
 
 AM_CONDITIONAL([WANT_TESTS], [test "x$enable_tests" != "xno"])
 
+###########################
+# gcov coverage reporting
+###########################
+AC_TDD_GCOV
+AM_CONDITIONAL([HAVE_GCOV], [test "x$ac_cv_check_gcov" = xyes])
+AM_CONDITIONAL([HAVE_LCOV], [test "x$ac_cv_check_lcov" = xyes])
+AM_CONDITIONAL([HAVE_GCOVR], [test "x$ac_cv_check_gcovr" = xyes])
+AC_SUBST(COVERAGE_CFLAGS)
+AC_SUBST(COVERAGE_LDFLAGS)
+
 dnl = Check for GLib Test Extensions (GTX) ====================================
 AC_ARG_ENABLE([extended-tests],
               AS_HELP_STRING([--enable-extended-tests=@<:@no/yes@:>@],[build extended test suite (requires libgtx from lp:gtx) @<:@default=no@:>@]),,
@@ -245,6 +255,7 @@
 
   Tests          : ${enable_tests}
   Extended Tests : ${enable_extended_tests}
+  Coverage       : ${use_gcov}
   Verbose logging: ${enable_trace_log}
 
   Extra CFlags   : ${CPPFLAGS} $MAINTAINER_CFLAGS
 
=== modified file 'src/Makefile.am'
--- src/Makefile.am	2012-11-28 08:53:48 +0000
+++ src/Makefile.am	2012-12-13 21:16:19 +0000
@@ -101,7 +101,8 @@
   $(DEE_LIBS)
 
 libdee_1_0_la_LDFLAGS = \
-  $(DEE_LT_LDFLAGS)
+  $(DEE_LT_LDFLAGS) \
+  $(COVERAGE_LDFLAGS)
 
 libdee_1_0_la_CPPFLAGS = \
 	-I$(srcdir) \
@@ -114,7 +115,8 @@
 	-DDEE_COMPILATION \
 	$(GCC_FLAGS) \
 	$(DEE_CFLAGS) \
-	$(MAINTAINER_CFLAGS)
+	$(MAINTAINER_CFLAGS) \
+	$(COVERAGE_CFLAGS)
 
 if HAVE_ICU
 devel_headers += dee-icu.h