Merge lp:~cjwatson/frame/cross into lp:frame

[Colin Watson]

Remove _CHECK_GTEST macro, and fix CHECK_GTEST to work correctly when cross-compiling.

Fix cross-building.

Firstly, the _CHECK_GTEST macro appears to be a cloned-and-hacked copy of CHECK_GTEST, and furthermore it's broken: observe that $have_gtest_source is tested but never set. It seems better to delete it in favour of the one that looks more likely to work.

Secondly, AC_CHECK_FILES doesn't work when cross-compiling, and fails hard, exiting the configure script. I chose to replace it with a compiler test: this is slower, but it avoids this problem. Of course, tests can't generally actually be run when cross-building unless you have qemu-user-static support or similar, but it still ought to be possible to perform the build. I've tested that this permits cross-building frame from amd64 to armhf.

From the looks of things, I suspect that these Autoconf macros exist in multiple Canonical projects. If there's an upstream source for them, or if I should submit matching MPs to other projects, please let me know.

[Daniel d'Andrada (dandrader)]

Looks ok.

review: Approve

=== modified file 'm4/gtest.m4'
--- m4/gtest.m4	2012-07-18 12:28:56 +0000
+++ m4/gtest.m4	2012-12-02 23:33:20 +0000
@@ -38,10 +38,18 @@
 
   GTEST_CPPFLAGS="$GTEST_CPPFLAGS -I$GTEST_SOURCE"
 
-  AC_CHECK_FILES([$GTEST_SOURCE/src/gtest-all.cc]
-                 [$GTEST_SOURCE/src/gtest_main.cc],
-                 [have_gtest=yes],
-                 [have_gtest=no])
+  AC_LANG_PUSH(C++)
+  gtest_save_CPPFLAGS=$CPPFLAGS
+  CPPFLAGS="$CPPFLAGS $GTEST_CPPFLAGS"
+  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include "src/gtest-all.cc"]])],
+                    [have_gtest=yes],
+                    [have_gtest=no])
+  AS_IF([test "x$have_gtest" = xyes],
+        [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include "src/gtest_main.cc"]])],
+                           [],
+                           [have_gtest=no])])
+  CPPFLAGS=$gtest_save_CPPFLAGS
+  AC_LANG_POP(C++)
 
   AS_IF([test "x$have_gtest" = xyes],
         [GTEST_LIBS=-lpthread

=== modified file 'm4/xorg-gtest.m4'
--- m4/xorg-gtest.m4	2012-06-21 19:41:40 +0000
+++ m4/xorg-gtest.m4	2012-12-02 23:33:20 +0000
@@ -1,4 +1,4 @@
-# serial 2
+# serial 3
 
 # Copyright (C) 2012 Canonical, Ltd.
 #
@@ -21,35 +21,6 @@
 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
 # SOFTWARE.
 
-# Checks whether the gtest source is available on the system. Allows for
-# adjusting the include and source path. Sets have_gtest=yes if the source is
-# present. Sets GTEST_CPPFLAGS and GTEST_SOURCE to the preprocessor flags and
-# source location respectively.
-AC_DEFUN([_CHECK_GTEST],
-[
-  AC_ARG_WITH([gtest-source-path],
-              [AS_HELP_STRING([--with-gtest-source-path],
-                              [location of the Google test sources, defaults to /usr/src/gtest])],
-              [GTEST_SOURCE="$withval"; GTEST_CPPFLAGS="-I$withval/include"],
-              [GTEST_SOURCE="/usr/src/gtest"])
-
-  AC_ARG_WITH([gtest-include-path],
-              [AS_HELP_STRING([--with-gtest-include-path],
-                              [location of the Google test headers])],
-              [GTEST_CPPFLAGS="-I$withval"])
-
-  GTEST_CPPFLAGS="$GTEST_CPPFLAGS -I$GTEST_SOURCE"
-
-  AC_CHECK_FILES([$GTEST_SOURCE/src/gtest-all.cc]
-                 [$GTEST_SOURCE/src/gtest_main.cc],
-                 [have_gtest=yes],
-                 [have_gtest=no])
-
-  AS_IF([test "x$have_gtest_source" = xyes],
-        [AC_SUBST(GTEST_CPPFLAGS)]
-        [AC_SUBST(GTEST_SOURCE)])
-]) # _CHECK_GTEST
-
 # CHECK_XORG_GTEST([ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 #
 # Checks whether the xorg-gtest source is available on the system. Allows for
@@ -61,7 +32,7 @@
 # Both default actions are no-ops.
 AC_DEFUN([CHECK_XORG_GTEST],
 [
-  AC_REQUIRE([_CHECK_GTEST])
+  AC_REQUIRE([CHECK_GTEST])
 
   PKG_CHECK_EXISTS([xorg-gtest],
                    [have_xorg_gtest=yes],