Merge lp:~zeller-benjamin/qtcreator-plugin-ubuntu/qmake-extras into lp:qtcreator-plugin-ubuntu

[Benjamin Zeller]

- Introduce ubuntu-sdk-qmake-extras package
- Fix bug lp:1395483 Qt Creator is no longer new

Introduce ubuntu-sdk-qmake-extras package

[lp:~zeller-benjamin/qtcreator-plugin-ubuntu/qmake-extras]

329. By Benjamin Zeller on 2015-01-16

Missing files

[PS Jenkins bot (ps-jenkins)]

PASSED: Continuous integration, rev:329
http://jenkins.qa.ubuntu.com/job/qtcreator-plugin-ubuntu-ci/492/
Executed test runs:
    SUCCESS: http://jenkins.qa.ubuntu.com/job/qtcreator-plugin-ubuntu-vivid-amd64-ci/26
    SUCCESS: http://jenkins.qa.ubuntu.com/job/qtcreator-plugin-ubuntu-vivid-armhf-ci/26

Click here to trigger a rebuild:
http://s-jenkins.ubuntu-ci:8080/job/qtcreator-plugin-ubuntu-ci/492/rebuild

review: Approve (continuous-integration)

[lp:~zeller-benjamin/qtcreator-plugin-ubuntu/qmake-extras]

330. By Benjamin Zeller on 2015-01-19

Fix bug lp:1395483 Qt Creator is no longer new

331. By Benjamin Zeller on 2015-01-19

Mark

[PS Jenkins bot (ps-jenkins)]

PASSED: Continuous integration, rev:331
http://jenkins.qa.ubuntu.com/job/qtcreator-plugin-ubuntu-ci/498/
Executed test runs:
    SUCCESS: http://jenkins.qa.ubuntu.com/job/qtcreator-plugin-ubuntu-vivid-amd64-ci/32
        deb: http://jenkins.qa.ubuntu.com/job/qtcreator-plugin-ubuntu-vivid-amd64-ci/32/artifact/work/output/*zip*/output.zip
    SUCCESS: http://jenkins.qa.ubuntu.com/job/qtcreator-plugin-ubuntu-vivid-armhf-ci/32

Click here to trigger a rebuild:
http://s-jenkins.ubuntu-ci:8080/job/qtcreator-plugin-ubuntu-ci/498/rebuild

review: Approve (continuous-integration)

=== modified file 'debian/control'
--- debian/control	2015-01-07 09:19:56 +0000
+++ debian/control	2015-01-19 11:13:51 +0000
@@ -74,7 +74,7 @@
             qtcreator-plugin-go,
             ubuntu-emulator
 Description: Ubuntu plugin for Qt Creator IDE
- Qt Creator is a new, lightweight, cross-platform integrated development
+ Qt Creator is a lightweight, cross-platform integrated development
  environment (IDE) designed to make development with the Qt application
  framework even faster and easier.
  .
@@ -90,13 +90,21 @@
 Replaces: qtcreator-plugin-ubuntu (<= 2.7.1-0ubuntu4),
 Conflicts: qtcreator-plugin-ubuntu (<= 2.7.1-0ubuntu4),
 Description: Common data files for the Ubuntu plugin for Qt Creator IDE
- Qt Creator is a new, lightweight, cross-platform integrated development
+ Qt Creator is a lightweight, cross-platform integrated development
  environment (IDE) designed to make development with the Qt application
  framework even faster and easier.
  .
  This package contains the runtime data files for the Ubuntu plugin for
  Qt Creator IDE.
 
+Package: ubuntu-sdk-qmake-extras
+Architecture: all
+Depends: ${misc:Depends},
+Description: Extra qmake features required by the Ubuntu-SDK templates,
+ extends qmake projects with Ubuntu specific variables and tools
+ .
+ This package contains qmake feature files for the Ubuntu-SDK
+
 Package: qtcreator-plugin-ubuntu-autopilot
 Architecture: any
 Depends: ${misc:Depends},

=== added file 'debian/ubuntu-sdk-qmake-extras.install'
--- debian/ubuntu-sdk-qmake-extras.install	1970-01-01 00:00:00 +0000
+++ debian/ubuntu-sdk-qmake-extras.install	2015-01-19 11:13:51 +0000
@@ -0,0 +1,2 @@
+usr/lib/*/qt5/mkspecs/features/ubuntu-click.prf
+usr/lib/*/qt5/mkspecs/features/ubuntu-click-tools.prf

=== modified file 'qtcreator-plugin-ubuntu.pro'
--- qtcreator-plugin-ubuntu.pro	2014-12-12 13:33:10 +0000
+++ qtcreator-plugin-ubuntu.pro	2015-01-19 11:13:51 +0000
@@ -2,3 +2,15 @@
 SUBDIRS = src/ubuntu \
           tests \
           chroot-agent
+
+OTHER_FILES +=  \
+    ubuntu-click.prf \
+    ubuntu-click-tools.prf \
+    share/qtcreator/ubuntu/scripts/*.py
+
+qt_install_libs = $$[QT_INSTALL_LIBS]
+QMAKE_INST_EXTRA_FILES.path=/lib/$$basename(qt_install_libs)/qt5/mkspecs/features
+QMAKE_INST_EXTRA_FILES.files= ubuntu-click.prf \
+                              ubuntu-click-tools.prf
+
+INSTALLS+=QMAKE_INST_EXTRA_FILES

=== modified file 'src/ubuntu/ubuntu.pro'
--- src/ubuntu/ubuntu.pro	2014-12-12 13:33:10 +0000
+++ src/ubuntu/ubuntu.pro	2015-01-19 11:13:51 +0000
@@ -52,7 +52,6 @@
     manifest.json.template \
     myapp.json.template \
     manifestlib.js \
-    $${PWD}/../../share/qtcreator/ubuntu/scripts/*.py \
     $$QML_FILES
 
 SOURCES += \

=== added file 'ubuntu-click-tools.prf'
--- ubuntu-click-tools.prf	1970-01-01 00:00:00 +0000
+++ ubuntu-click-tools.prf	2015-01-19 11:13:51 +0000
@@ -0,0 +1,90 @@
+#handle and install the manifest file
+
+!defined(UBUNTU_CLICK_ARCH) {
+    load(ubuntu-click)
+}
+
+defineTest(ubuntuAddPreTargetDep) {
+    equals(TEMPLATE,subdirs) {
+        #this hack adds a extra "first" target dependency
+        #because subdirs can not handle build dependencies
+        isEmpty(target_first.target){
+            target_first.target = first
+            QMAKE_EXTRA_TARGETS += target_first
+            export(QMAKE_EXTRA_TARGETS)
+        }
+        target_first.depends += $$1
+
+        export(target_first)
+        export(target_first.target)
+        export(target_first.depends)
+    } else {
+        PRE_TARGETDEPS+=$$1
+        export(PRE_TARGETDEPS)
+    }
+}
+
+!isEmpty(UBUNTU_MANIFEST_FILE){
+    OTHER_FILES+=$$UBUNTU_MANIFEST_FILE
+    manifest_file.target   = $$OUT_PWD/manifest.json
+    manifest_file.commands = sed s/@CLICK_ARCH@/$$UBUNTU_CLICK_ARCH/g $$absolute_path($${UBUNTU_MANIFEST_FILE},$$_PRO_FILE_PWD_) > $${manifest_file.target}
+    manifest_file.depends  = $$absolute_path($${UBUNTU_MANIFEST_FILE},$$_PRO_FILE_PWD_)
+
+    QMAKE_EXTRA_TARGETS+=manifest_file
+    ubuntuAddPreTargetDep($${manifest_file.target})
+
+    manifest_file_install.path  = /
+    manifest_file_install.files = $${OUT_PWD}/manifest.json
+    manifest_file_install.CONFIG +=no_check_exist
+    INSTALLS+=manifest_file_install
+}
+
+!isEmpty(UBUNTU_TRANSLATION_SOURCES){
+    # iterate over all QML/JS files and create a basic translation template
+    template_pot.target=$$_PRO_FILE_PWD_/po/template.pot
+    for(filelist, UBUNTU_TRANSLATION_SOURCES) {
+        resolved_filelist = $$absolute_path($$filelist,$$_PRO_FILE_PWD_)
+        resolved_filelist = $$files($$resolved_filelist)
+        for(file,resolved_filelist) {
+            template_pot.depends+=$$file
+        }
+
+    }
+
+    !isEmpty(template_pot.depends) {
+        template_pot.commands=mkdir -p $$_PRO_FILE_PWD_/po && xgettext -o $$template_pot.target --qt --c++ --add-comments=TRANSLATORS --keyword=tr --keyword=tr:1,2 $$template_pot.depends --from-code=UTF-8
+
+        QMAKE_EXTRA_TARGETS+=template_pot
+        ubuntuAddPreTargetDep($$_PRO_FILE_PWD_/po/template.pot)
+    }
+
+    !isEmpty(UBUNTU_PO_FILES){
+        isEmpty(UBUNTU_TRANSLATION_DOMAIN):error("UBUNTU_TRANSLATION_DOMAIN not defined")
+        # compile the mo files into po files
+        for(filelist, UBUNTU_PO_FILES) {
+            resolved_filelist = $$absolute_path($$filelist,$$_PRO_FILE_PWD_)
+            resolved_filelist = $$files($$resolved_filelist)
+            for(file,resolved_filelist) {
+                lang=$$basename(file)
+                lang=$$split(lang, .)
+                lang=$$first(lang)
+
+                target_name=mo_target_$$lang
+                target_file=$$shadowed($$_PRO_FILE_PWD_)/po/$${lang}/$${UBUNTU_TRANSLATION_DOMAIN}.mo
+
+                $${target_name}.target=$$target_file
+                $${target_name}.commands=mkdir -p po/$${lang} && msgfmt -o $${target_file} $$absolute_path($$file,$$_PRO_FILE_PWD_)
+                $${target_name}.depends+=$$absolute_path($$file,$$_PRO_FILE_PWD_)
+
+                $${target_name}_inst.path =/share/locale/$${lang}/LC_MESSAGES
+                $${target_name}_inst.CONFIG +=no_check_exist
+                $${target_name}_inst.files=$$target_file
+
+                QMAKE_EXTRA_TARGETS+=$$target_name
+                ubuntuAddPreTargetDep($${target_file})
+
+                INSTALLS += $${target_name}_inst
+            }
+        }
+    }
+}

=== added file 'ubuntu-click.prf'
--- ubuntu-click.prf	1970-01-01 00:00:00 +0000
+++ ubuntu-click.prf	2015-01-19 11:13:51 +0000
@@ -0,0 +1,6 @@
+UBUNTU_CLICK_ARCH=$$system(dpkg-architecture -qDEB_HOST_ARCH)
+qt_install_libs = $$[QT_INSTALL_LIBS]
+UBUNTU_CLICK_PLUGIN_PATH=/lib/$$basename(qt_install_libs)
+UBUNTU_CLICK_BINARY_PATH=/lib/$$basename(qt_install_libs)/bin
+
+!contains(CONFIG,ubuntu-click-tools):CONFIG+=ubuntu-click-tools