Merge lp:~trond-norbye/pandora-build/innodb into lp:pandora-build

[Trond Norbye]

[Trond Norbye (trond-norbye)]

Added support for embedded innodb. Unfortunately the test includes the version number of in the path for the headerfile, but that's the way they install the header... I guess we should file a RFE for them to install the header without the version number in the path the next time, and fix the test when the new version is released.

=== added file 'm4/pandora_have_innodb.m4'
--- m4/pandora_have_innodb.m4	1970-01-01 00:00:00 +0000
+++ m4/pandora_have_innodb.m4	2009-09-21 08:23:04 +0000
@@ -0,0 +1,41 @@
+dnl  Copyright (C) 2009 Sun Microsystems
+dnl This file is free software; Sun Microsystems
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([_PANDORA_SEARCH_LIBINNODB],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  dnl --------------------------------------------------------------------
+  dnl  Check for libinnodb
+  dnl --------------------------------------------------------------------
+
+  AC_ARG_ENABLE([libinnodb],
+    [AS_HELP_STRING([--disable-libinnodb],
+      [Build with libinnodb support @<:@default=on@:>@])],
+    [ac_enable_libinnodb="$enableval"],
+    [ac_enable_libinnodb="yes"])
+
+  AS_IF([test "x$ac_enable_libinnodb" = "xyes"],[
+    AC_LIB_HAVE_LINKFLAGS(innodb,,[
+      #include <embedded_innodb-1.0/innodb.h>
+    ],[
+      ib_u64_t
+      ib_api_version(void);
+    ])
+  ],[
+    ac_cv_libinnodb="no"
+  ])
+
+  AM_CONDITIONAL(HAVE_LIBINNODB, [test "x${ac_cv_libinnodb}" = "xyes"])
+])
+
+AC_DEFUN([PANDORA_HAVE_LIBINNODB],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBINNODB])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_LIBINNODB],[
+  AC_REQUIRE([PANDORA_HAVE_LIBINNODB])
+  AS_IF([test "x${ac_cv_libinnodb}" = "xno"],
+      AC_MSG_ERROR([libinnodb is required for ${PACKAGE}]))
+])