Merge lp:~ter0/pantheon-terminal/add-uninstall-target into lp:~elementary-apps/pantheon-terminal/trunk

[Chris Johns]

Add uninstall target

[David Gomes (davidgomes)]

I don't think I'm really the one to review this, I'm going to ask Ricotz to review this though.

[xapantu (xapantu)]

I am not opposed to this one but that should definitively be in the cmake-modules branch. I will add it if it works fine.

[xapantu (xapantu)]

review: Approve

=== modified file 'CMakeLists.txt'
--- CMakeLists.txt	2013-12-23 21:04:12 +0000
+++ CMakeLists.txt	2014-01-28 14:21:26 +0000
@@ -37,6 +37,15 @@
 include (CPack)
 add_custom_target (dist COMMAND ${CMAKE_MAKE_PROGRAM} package_source)
 
+# Add 'make uninstall' command to remove installed files
+configure_file(
+    "${CMAKE_SOURCE_DIR}/cmake/Uninstall.cmake"
+    "${CMAKE_CURRENT_BINARY_DIR}/Uninstall.cmake"
+    IMMEDIATE @ONLY)
+
+add_custom_target(uninstall
+    COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/Uninstall.cmake)
+
 find_package (PkgConfig)
 pkg_check_modules (DEPS REQUIRED
   gthread-2.0

=== added file 'cmake/Uninstall.cmake'
--- cmake/Uninstall.cmake	1970-01-01 00:00:00 +0000
+++ cmake/Uninstall.cmake	2014-01-28 14:21:26 +0000
@@ -0,0 +1,23 @@
+if (NOT EXISTS "@CMAKE_CURRENT_BINARY_DIR@/install_manifest.txt")
+    message(FATAL_ERROR "Cannot find install manifest: \"@CMAKE_CURRENT_BINARY_DIR@/install_manifest.txt\"")
+endif(NOT EXISTS "@CMAKE_CURRENT_BINARY_DIR@/install_manifest.txt")
+
+file(READ "@CMAKE_CURRENT_BINARY_DIR@/install_manifest.txt" files)
+string(REGEX REPLACE "\n" ";" files "${files}")
+cmake_policy (SET CMP0007 NEW)
+list(REVERSE files)
+foreach (file ${files})
+    message(STATUS "Uninstalling \"$ENV{DESTDIR}${file}\"")
+    if (EXISTS "$ENV{DESTDIR}${file}")
+        execute_process(
+            COMMAND @CMAKE_COMMAND@ -E remove "$ENV{DESTDIR}${file}"
+            OUTPUT_VARIABLE rm_out
+            RESULT_VARIABLE rm_retval
+        )
+        if(NOT ${rm_retval} EQUAL 0)
+            message(FATAL_ERROR "Problem when removing \"$ENV{DESTDIR}${file}\"")
+        endif (NOT ${rm_retval} EQUAL 0)
+    else (EXISTS "$ENV{DESTDIR}${file}")
+        message(STATUS "File \"$ENV{DESTDIR}${file}\" does not exist.")
+    endif (EXISTS "$ENV{DESTDIR}${file}")
+endforeach(file)