Merge lp:~smspillaz/compiz-core/compiz-core.dist-buildsystem into lp:compiz-core/trunk

[Sam Spilsbury]

Adds new release targets to the buildsystem

make release-prep: generates NEWS ChangeLog and AUTHORS file
make distcheck: generates a tarball
make release-signoff: signs the tarball using the key in RELEASE_KEY and if
in a git repository, creates tags and branches for that

[lp:~smspillaz/compiz-core/compiz-core.dist-buildsystem]

2760. By Sam Spilsbury on 2011-07-07

Add various fixes for distcheck, source distributions without a VCS
and non-C sources (eg python bindings where we can't do try_compile
because C and CXX are not in the enabled languages)

[Aurélien Gâteau (agateau)]

(disclaimer: I only read the diff, didn't try it for real)

Some questions and suggestions:

1. You could get rid of one line when reading the version number by directly using the VERSION variable instead of an intermediate COMPIZ_RELEASE_VERSION one.

2. is there a real reason to support both bz2 and gz? I would expect everybody to be able to decode bz2 now. Supporting only bz2 would simplify this diff quite a bit.

3. The check for whether you are in a git or a bzr repository could be moved outside the macros to avoid duplication. I would also simplify it to something like this (untested):

if (IS_DIRECTORY ${CMAKE_SOURCE_DIR}/.git)
    set(IS_GIT_REPO TRUE)
elseif (IS_DIRECTORY ${CMAKE_SOURCE_DIR}/.git)
    set(IS_GIT_REPO FALSE)
endif (IS_DIRECTORY ${CMAKE_SOURCE_DIR}/.git)

if (IS_DIRECTORY ${CMAKE_SOURCE_DIR}/.bzr)
    set(IS_BZR_REPO TRUE)
elseif (IS_DIRECTORY ${CMAKE_SOURCE_DIR}/.bzr)
    set(IS_BZR_REPO FALSE)
endif (IS_DIRECTORY ${CMAKE_SOURCE_DIR}/.bzr)

You can then replace your tests with easier-to-read checks on IS_GIT_REPO and IS_BZR_REPO

[lp:~smspillaz/compiz-core/compiz-core.dist-buildsystem]

2761. By Sam Spilsbury on 2011-07-07

Drop support for bz2, add targets for release uploads, cleanup

[Aurélien Gâteau (agateau)]

Looks nicer, just two minor nitpicks:
1. The "if" cmake command allows you to simplify the tests from "if (${IS_GIT_REPO})" to "if (IS_GIT_REPO)".
2. There is some commented code, not sure if it is intentional or not.

[lp:~smspillaz/compiz-core/compiz-core.dist-buildsystem]

2762. By Sam Spilsbury on 2011-07-07

Nitpicking and fix FTBFS on bzr

[Jason Smith (jassmith)]

Can this be run by someone without commit access to compiz?

[Jason Smith (jassmith)]

+1

review: Approve

[Sam Spilsbury (smspillaz)]

Yes, the targets are independent of each other

release-prep: updates the NEWS, ChangeLog, AUTHORS (in /build, NOT in the working tree)
distcheck: checks for build failure, does tests
release-signoff: creates git branches, tags, copies NEWS etc into working tree, commits, updates tarball, signs it + checksums it and bumps VERSION
release-push: pushes objects into git
release-upload: uploads tarball to releases.compiz.org

=== modified file 'CMakeLists.txt'
--- CMakeLists.txt	2011-07-06 19:52:01 +0000
+++ CMakeLists.txt	2011-07-07 16:29:45 +0000
@@ -15,13 +15,10 @@
     set (CMAKE_BUILD_TYPE "Debug" CACHE STRING "Build type (Debug/Release/RelWithDebInfo/MinSizeRe)" FORCE)
 endif (NOT CMAKE_BUILD_TYPE)
 
-# compiz package version number
-# An odd micro number indicates in-progress development.
-# An even micro number indicates a released version.
-set (COMPIZ_VERSION_MAJOR 0)
-set (COMPIZ_VERSION_MINOR 9)
-set (COMPIZ_VERSION_MICRO 5)
-set (VERSION ${COMPIZ_VERSION_MAJOR}.${COMPIZ_VERSION_MINOR}.${COMPIZ_VERSION_MICRO})
+file (READ ${CMAKE_SOURCE_DIR}/VERSION COMPIZ_RELEASE_VERSION LIMIT 12 OFFSET 0)
+string (STRIP ${COMPIZ_RELEASE_VERSION} COMPIZ_RELEASE_VERSION)
+
+set (VERSION ${COMPIZ_RELEASE_VERSION})
 
 set (DECOR_INTERFACE_VERSION 20110504)
 
@@ -126,6 +123,9 @@
 compiz_package_generation ("Compiz")
 compiz_add_uninstall ()
 compiz_add_git_dist ()
+compiz_add_distcheck ()
+compiz_add_release ()
+compiz_add_release_signoff ()
 
 _print_configure_results ()
 

=== added file 'VERSION'
--- VERSION	1970-01-01 00:00:00 +0000
+++ VERSION	2011-07-07 16:29:45 +0000
@@ -0,0 +1,1 @@
+0.9.5.0

=== modified file 'cmake/CompizCommon.cmake'
--- cmake/CompizCommon.cmake	2011-02-22 11:27:28 +0000
+++ cmake/CompizCommon.cmake	2011-07-07 16:29:45 +0000
@@ -49,6 +49,24 @@
     set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall")
 endif ()
 
+if (IS_DIRECTORY ${CMAKE_SOURCE_DIR}/.git)
+    set(IS_GIT_REPO 1)
+else (IS_DIRECTORY ${CMAKE_SOURCE_DIR}/.git)
+    set(IS_GIT_REPO 0)
+endif (IS_DIRECTORY ${CMAKE_SOURCE_DIR}/.git)
+
+if (IS_DIRECTORY ${CMAKE_SOURCE_DIR}/.gitmodules)
+    set(IS_GIT_SUBMODULES_REPO 1)
+else (IS_DIRECTORY ${CMAKE_SOURCE_DIR}/.gitmodules)
+    set(IS_GIT_SUBMODULES_REPO 0)
+endif (IS_DIRECTORY ${CMAKE_SOURCE_DIR}/.gitmodules)
+
+if (IS_DIRECTORY ${CMAKE_SOURCE_DIR}/.bzr)
+    set(IS_BZR_REPO 1)
+elseif (IS_DIRECTORY ${CMAKE_SOURCE_DIR}/.bzr)
+    set(IS_BZR_REPO 0)
+endif (IS_DIRECTORY ${CMAKE_SOURCE_DIR}/.bzr)
+
 function (compiz_ensure_linkage)
     find_program (LDCONFIG_EXECUTABLE ldconfig)
     mark_as_advanced (FORCE LDCONFIG_EXECUTABLE)
@@ -64,12 +82,243 @@
 endfunction ()
 
 macro (compiz_add_git_dist)
-    set(ARCHIVE_NAME ${CMAKE_PROJECT_NAME}-${VERSION})
-    add_custom_target(dist
-	COMMAND git archive --prefix=${ARCHIVE_NAME}/ HEAD
-		| bzip2 > ${CMAKE_BINARY_DIR}/${ARCHIVE_NAME}.tar.bz2
-	WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
-endmacro ()
+
+	# Try to use the git and bzr inbuilt functions for generating
+	# archives first, otherwise do it manually
+	if (${IS_GIT_REPO})
+
+		if (${IS_GIT_SUBMODULES_REPO})
+			find_program (GIT_ARCHIVE_ALL git-archive-all.sh)
+
+			if (NOT (${GIT_ARCHIVE_ALL} STREQUAL "GIT_ARCHIVE_ALL-NOTFOUND"))
+				add_custom_target (dist ${GIT_ARCHIVE_ALL} --prefix ${CMAKE_PROJECT_NAME}-${VERSION}/ ${CMAKE_BINARY_DIR}/${CMAKE_PROJECT_NAME}-${VERSION}.tar
+						   COMMAND bzip2 ${CMAKE_BINARY_DIR}/${CMAKE_PROJECT_NAME}-${VERSION}.tar
+						   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+						   COMMENT "Creating bz2 archive")
+			else (NOT (${GIT_ARCHIVE_ALL} STREQUAL "GIT_ARCHIVE_ALL-NOTFOUND"))
+				message ("[WARNING]: git-archive-all.sh is needed to make releases of git submodules, get it from https://github.com/meitar/git-archive-all.sh.git and install it into your PATH")
+			endif (NOT (${GIT_ARCHIVE_ALL} STREQUAL "GIT_ARCHIVE_ALL-NOTFOUND"))
+		else (${IS_GIT_SUBMODULES_REPO})
+			add_custom_target (dist git archive --format=tar --prefix ${CMAKE_PROJECT_NAME}-${VERSION}/ -o ${CMAKE_BINARY_DIR}/${CMAKE_PROJECT_NAME}-${VERSION}.tar HEAD
+						   COMMAND bzip2 ${CMAKE_BINARY_DIR}/${CMAKE_PROJECT_NAME}-${VERSION}.tar
+						   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+						   COMMENT "Creating bz2 archive")
+		endif (${IS_GIT_SUBMODULES_REPO})
+	else (${IS_GIT_REPO})
+		if (${IS_BZR_REPO})
+			add_custom_target (dist
+					   COMMAND bzr export --root=${CMAKE_PROJECT_NAME}-${VERSION} ${CMAKE_BINARY_DIR}/${CMAKE_PROJECT_NAME}-${VERSION}.tar.bz2
+					   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
+		else (${IS_BZR_REPO})
+			add_custom_target (dist)
+			#add_custom_target (dist 
+			#		   COMMAND tar -cvf ${CMAKE_SOURCE_DIR} | bzip2 > ${CMAKE_BINARY_DIR}/${CMAKE_PROJECT_NAME}-${VERSION}.tar.bz2
+			#		   WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/../)
+		endif (${IS_BZR_REPO})
+	endif (${IS_GIT_REPO})
+
+endmacro ()
+
+macro (compiz_add_distcheck)
+	add_custom_target (distcheck 
+			   COMMAND mkdir -p ${CMAKE_BINARY_DIR}/dist-build
+			   && cp ${CMAKE_BINARY_DIR}/${CMAKE_PROJECT_NAME}-${VERSION}.tar.bz2 ${CMAKE_BINARY_DIR}/dist-build
+			   && cd ${CMAKE_BINARY_DIR}/dist-build
+			   && tar xvf ${CMAKE_BINARY_DIR}/dist-build/${CMAKE_PROJECT_NAME}-${VERSION}.tar.bz2
+			   && mkdir -p ${CMAKE_BINARY_DIR}/dist-build/${CMAKE_PROJECT_NAME}-${VERSION}/build
+			   && cd ${CMAKE_BINARY_DIR}/dist-build/${CMAKE_PROJECT_NAME}-${VERSION}/build
+			   && cmake -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_DIR}/dist-build/buildroot -DCOMPIZ_PLUGIN_INSTALL_TYPE='package' .. -DCMAKE_MODULE_PATH=/usr/share/cmake -DCOMPIZ_DISABLE_PLUGIN_KDE=ON
+			   && make -j4
+			   && make -j4 install
+			   WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
+	add_dependencies (distcheck dist)
+endmacro ()
+
+macro (compiz_add_release_signoff)
+
+	add_custom_target (release-signoff)
+
+	add_custom_target (release-update-working-tree
+			   COMMAND cp NEWS ${CMAKE_SOURCE_DIR} &&
+				   cp AUTHORS ${CMAKE_SOURCE_DIR} &&
+				   cp ChangeLog ${CMAKE_SOURCE_DIR}) 
+
+	if (${IS_GIT_REPO})
+		add_custom_target (release-commits
+				   COMMAND git commit -a -m "Update NEWS for ${VERSION}"
+				   COMMENT "Release Commit"
+				   WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
+		add_custom_target (release-tags
+				   COMMAND git tag -u $ENV{RELEASE_KEY} compiz-${VERSION} HEAD -m "Compiz ${VERSION} Release"
+				   COMMENT "Release Tags"
+				   WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
+		add_custom_target (release-branch
+				   COMMAND git checkout -b compiz-${VERSION}-series && 
+				   touch RELEASED && 
+				   git add RELEASED &&
+				   cat VERSION > RELEASED &&
+				   git commit -a -m "Add RELEASED file"
+				   COMMENT "Release Branch"
+				   WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
+		add_custom_target (release-update-dist
+				   COMMAND git checkout master &&
+				   rm ${CMAKE_PROJECT_NAME}-${VERSION}.tar.bz2 &&
+				   make dist
+				   COMMENT "Updating bz2 archive"
+				   WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
+		add_custom_target (release-version-bump
+				   COMMAND git checkout master &&
+				   $ENV{EDITOR} VERSION &&
+				   git add VERSION &&
+				   git commit VERSION -m "Bump VERSION"
+				   COMMENT "Bumping VERSION"
+				   WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
+	else (${IS_GIT_REPO})
+	    add_custom_target (release-commits)
+	    add_custom_target (release-tags)
+	    add_custom_target (release-branch)
+	    add_custom_target (release-update-dist)
+	    add_custom_target (release-version-bump)
+
+	endif (${IS_GIT_REPO})
+
+	add_custom_target (release-sign-tarballs
+		   COMMAND gpg --armor --sign --detach-sig ${CMAKE_PROJECT_NAME}-${VERSION}.tar.bz2
+	   COMMENT "Signing tarball"
+	   WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
+	add_custom_target (release-sha1-tarballs
+		   COMMAND sha1sum ${CMAKE_PROJECT_NAME}-${VERSION}.tar.bz2 > ${CMAKE_PROJECT_NAME}-${VERSION}.tar.bz2.sha1
+		   COMMENT "SHA1Summing tarball"
+		   WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
+	add_custom_target (release-sign-sha1-tarballs
+		   COMMAND gpg --armor --sign --detach-sig ${CMAKE_PROJECT_NAME}-${VERSION}.tar.bz2.sha1
+		   COMMENT "Signing SHA1Sum checksum"
+		   WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
+
+	add_dependencies (release-commits release-update-working-tree)
+	add_dependencies (release-tags release-commits)
+	add_dependencies (release-branch release-tags)
+	add_dependencies (release-update-dist release-branch)
+	add_dependencies (release-version-bump release-update-dist)
+	add_dependencies (release-sign-tarballs release-version-bump)
+	add_dependencies (release-sha1-tarballs release-sign-tarballs)
+	add_dependencies (release-sign-sha1-tarballs release-sha1-tarballs)
+
+	# This means that releasing needs to be done from a git repo for now
+	# But that's fine
+	add_dependencies (release-signoff release-sign-sha1-tarballs)
+
+	# Actually pushes the release
+	if (${IS_GIT_REPO})
+		add_custom_target (push-master
+				   COMMAND git push origin master
+				   COMMENT "Pushing to master"
+				   WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
+		add_custom_target (push-release-branch
+				   COMMAND git push origin compiz-${VERISON}-series
+				   COMMENT "Pushing to compiz-${VERISON}-series"
+				   WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
+		add_custom_target (push-tag
+				   COMMAND git push origin compiz-${VERSION}
+				   COMMENT "Pushing tag compiz-${VERSION}"
+				   WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
+	else (${IS_GIT_REPO})
+		add_custom_target (push-master)
+		add_custom_target (push-release-branch)
+		add_custom_target (push-tag)
+	endif (${IS_GIT_REPO})
+
+	add_custom_target (release-push)
+
+	add_dependencies (release-push push-release-branch)
+	add_dependencies (push-release-branch push-tag)
+	add_dependencies (push-tag push-master)
+
+	# Push the tarball to releases.compiz.org
+	set (COMPIZ_RELEASE_UPLOAD_HOST 	releases.compiz.org)
+	set (COMPIZ_RELEASE_UPLOAD_BASE 	/home/releases)
+	set (COMPIZ_RELEASE_UPLOAD_DIR_VERSION	${COMPIZ_RELEASE_UPLOAD_BASE}/${VERSION}/)
+	set (COMPIZ_RELEASE_UPLOAD_DIR_COMPONENT ${COMPIZ_RELEASE_UPLOAD_BASE}/components/${CMAKE_PROJECT_NAME})
+
+	message ("releasing to " ${COMPIZ_RELEASE_UPLOAD_HOST})
+	message (" base: " ${COMPIZ_RELEASE_UPLOAD_BASE})
+	message (" version: " ${COMPIZ_RELEASE_UPLOAD_BASE}/${VERSION})
+	message (" component: ${COMPIZ_RELEASE_UPLOAD_BASE}/components/${CMAKE_PROJECT_NAME}")
+
+	add_custom_target (release-upload-version
+			   COMMAND ssh $ENV{USER}@${COMPIZ_RELEASE_UPLOAD_HOST} "mkdir -p ${COMPIZ_RELEASE_UPLOAD_BASE}/${VERSION}" && scp ${CMAKE_PROJECT_NAME}-${VERSION}.tar.bz2 $ENV{USER}@${COMPIZ_RELEASE_UPLOAD_HOST}:${COMPIZ_RELEASE_UPLOAD_DIR_VERSION}
+			   COMMENT "Uploading ${CMAKE_PROJECT_NAME}-${VERSION} to ${VERSION}"
+			   WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
+
+	# Does nothing for now
+	add_custom_target (release-upload-component)
+	#add_custom_target (release-upload-component
+	#		   COMMAND ssh $ENV{USER}@${COMPIZ_RELEASE_UPLOAD_HOST} "mkdir -p ${COMPIZ_RELEASE_UPLOAD_BASE}/${VERSION}" && scp ${CMAKE_PROJECT_NAME}-${VERSION}.tar.bz2 ${CMAKE_PROJECT_NAME}-${VERSION}.tar.bz2.asc ${CMAKE_PROJECT_NAME}-${VERSION}.tar.bz2.sha1 ${CMAKE_PROJECT_NAME}-${VERSION}.tar.bz2.sha1.asc $ENV{USER}@${COMPIZ_RELEASE_UPLOAD_HOST}:${COMPIZ_RELEASE_UPLOAD_BASE_DIR_COMPONENT}
+	#		   COMMENT "Uploading ${CMAKE_PROJECT_NAME}-${VERSION} to ${CMAKE_PROJECT_NAME}/${VERSION}"
+	#		   WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
+
+	add_custom_target (release-upload)
+
+	add_dependencies (release-upload-component release-upload-version)
+	add_dependencies (release-upload release-upload-component)
+
+endmacro ()
+
+macro (compiz_add_release)
+
+	if (${IS_GIT_REPO})
+		find_program (GEN_GIT_LOG gen-git-log.sh)
+		add_custom_target (authors
+				   COMMAND git shortlog -se | cut -c8- > AUTHORS
+				   COMMENT "Generating AUTHORS"
+				   WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
+		if (NOT (${GEN_GIT_LOG} STREQUAL "GEN_GIT_LOG-NOTFOUND"))
+			add_custom_target (changelog
+					   COMMAND ${GEN_GIT_LOG} > ChangeLog
+					   COMMENT "Generating ChangeLog"
+					   WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
+		else (NOT (${GEN_GIT_LOG} STREQUAL "GEN_GIT_LOG-NOTFOUND"))
+			message ("[WARNING]: gen-git-log.sh is required to make releases, ensure that it is installed into your PATH")
+		endif (NOT (${GEN_GIT_LOG} STREQUAL "GEN_GIT_LOG-NOTFOUND"))
+
+		add_custom_target (news-header echo 'Release ${VERSION} ('`date +%Y-%m-%d`' '`git config user.name`' <'`git config user.email`'>)' > ${CMAKE_BINARY_DIR}/NEWS.update && seq -s "=" `cat ${CMAKE_BINARY_DIR}/NEWS.update | wc -c` | sed 's/[0-9]//g' >> ${CMAKE_BINARY_DIR}/NEWS.update && $ENV{EDITOR} ${CMAKE_BINARY_DIR}/NEWS.update && echo >> ${CMAKE_BINARY_DIR}/NEWS.update
+				   COMMAND $ENV{EDITOR} ${CMAKE_BINARY_DIR}/NEWS.update
+				   COMMENT "Generating NEWS Header"
+				   WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
+	else (${IS_GIT_REPO})
+		if (${IS_BZR_REPO})
+			add_custom_target (authors
+					   COMMAND bzr log --long --levels=0 | grep -e "^\\s*author:" -e "^\\s*committer:" | cut -d ":" -f 2 | sort -u > AUTHORS
+					   COMMENT "Generating AUTHORS")
+			add_custom_target (changelog
+					   COMMAND bzr log --gnu-changelog > ChangeLog
+					   COMMENT "Generating ChangeLog")
+
+			add_custom_target (news-header echo > ${CMAKE_BINARY_DIR}/NEWS.update
+					   COMMAND echo 'Release ${VERSION} ('`date +%Y-%m-%d`' '`bzr config email`')' > ${CMAKE_BINARY_DIR}/NEWS.update && seq -s "=" `cat ${CMAKE_BINARY_DIR}/NEWS.update | wc -c` | sed 's/[0-9]//g' >> ${CMAKE_BINARY_DIR}/NEWS.update && $ENV{EDITOR} ${CMAKE_BINARY_DIR}/NEWS.update && echo >> ${CMAKE_BINARY_DIR}/NEWS.update
+					   COMMENT "Generating NEWS Header"
+					   WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
+		else (${IS_BZR_REPO})
+			add_custom_target (authors)
+			add_custom_target (changelog)
+			add_custom_target (news-header)
+		endif (${IS_BZR_REPO})
+	endif (${IS_GIT_REPO})
+
+	add_custom_target (news
+			   COMMAND cat ${CMAKE_SOURCE_DIR}/NEWS > NEWS.old &&
+				   cat NEWS.old >> ${CMAKE_BINARY_DIR}/NEWS.update &&
+				   cat NEWS.update > NEWS
+			   WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
+
+	add_dependencies (changelog authors)
+	add_dependencies (news-header changelog)
+	add_dependencies (news news-header)
+
+	add_custom_target (release-prep)
+	add_dependencies (release-prep news)
+
+endmacro (compiz_add_release)
 
 # unsets the given variable
 macro (compiz_unset var)
@@ -120,6 +369,7 @@
 endfunction ()
 
 function (compiz_add_plugins_in_folder folder)
+    set (COMPIZ_PLUGIN_PACK_BUILD 1)
     file (
         GLOB _plugins_in
         RELATIVE "${folder}"
@@ -256,21 +506,23 @@
 endmacro ()
 
 #posix 2008 scandir check
-include (CheckCXXSourceCompiles)
-CHECK_CXX_SOURCE_COMPILES (
-  "# include <dirent.h>
-   int func (const char *d, dirent ***list, void *sort)
-   {
-     int n = scandir(d, list, 0, (int(*)(const dirent **, const dirent **))sort);
-     return n;
-   }
+if (CMAKE_CXX_COMPILER)
+	include (CheckCXXSourceCompiles)
+	CHECK_CXX_SOURCE_COMPILES (
+	  "# include <dirent.h>
+	   int func (const char *d, dirent ***list, void *sort)
+	   {
+	     int n = scandir(d, list, 0, (int(*)(const dirent **, const dirent **))sort);
+	     return n;
+	   }
 
-   int main (int, char **)
-   {
-     return 0;
-   }
-  "
-  HAVE_SCANDIR_POSIX)
+	   int main (int, char **)
+	   {
+	     return 0;
+	   }
+	  "
+	  HAVE_SCANDIR_POSIX)
+endif (CMAKE_CXX_COMPILER)
 
 if (HAVE_SCANDIR_POSIX)
   add_definitions (-DHAVE_SCANDIR_POSIX)

=== modified file 'cmake/CompizPlugin.cmake'
--- cmake/CompizPlugin.cmake	2011-05-17 23:51:02 +0000
+++ cmake/CompizPlugin.cmake	2011-07-07 16:29:45 +0000
@@ -423,6 +423,12 @@
 
 	compiz_add_uninstall ()
 
+	if (NOT COMPIZ_PLUGIN_PACK_BUILD)
+		compiz_add_git_dist ()
+		compiz_add_release ()
+		compiz_add_release_signoff ()
+	endif (NOT COMPIZ_PLUGIN_PACK_BUILD)
+
     else ()
 	message (STATUS "[WARNING] One or more dependencies for compiz plugin ${plugin} not found. Skipping plugin.")
 	message (STATUS "Missing dependencies :${COMPIZ_${_PLUGIN}_MISSING_DEPS}")

=== modified file 'include/compiz-common.h.in'
--- include/compiz-common.h.in	2009-03-15 23:01:06 +0000
+++ include/compiz-common.h.in	2011-07-07 16:29:45 +0000
@@ -1,9 +1,5 @@
 #ifndef COMPIZ_COMMON_H
 #define COMPIZ_COMMON_H
 
-#define COMPIZ_VERSION_MAJOR @COMPIZ_VERSION_MAJOR@
-#define COMPIZ_VERSION_MINOR @COMPIZ_VERSION_MINOR@
-#define COMPIZ_VERSION_MICRO @COMPIZ_VERSION_MICRO@
-
-#define COMPIZ_VERSION_STRING "@COMPIZ_VERSION_MAJOR@.@COMPIZ_VERSION_MINOR@.@COMPIZ_VERSION_MICRO@"
+#define COMPIZ_VERSION_STRING "@VERSION@"
 #endif