Merge lp:~mohyt/drizzle/trunk-bug-1116980 into lp:drizzle

[Mohit Srivastava]

[Stewart Smith (stewart)]

review: Approve

=== added file 'm4/pandora_have_libevent.m4'
--- m4/pandora_have_libevent.m4	1970-01-01 00:00:00 +0000
+++ m4/pandora_have_libevent.m4	2013-02-06 08:17:22 +0000
@@ -0,0 +1,79 @@
+dnl  Copyright (C) 2009 Sun Microsystems, Inc.
+dnl This file is free software; Sun Microsystems, Inc.
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+#--------------------------------------------------------------------
+# Check for libevent
+#--------------------------------------------------------------------
+
+
+AC_DEFUN([_PANDORA_SEARCH_LIBEVENT],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  AC_LIB_HAVE_LINKFLAGS(event,,
+  [
+    #include <sys/types.h>
+    #include <sys/time.h>
+    #include <stdlib.h>
+    #include <event.h>
+  ],[
+    struct bufferevent bev;
+    bufferevent_settimeout(&bev, 1, 1);
+    event_init();
+    event_loop(EVLOOP_ONCE);
+  ]) 
+
+  AM_CONDITIONAL(HAVE_LIBEVENT, [test "x${ac_cv_libevent}" = "xyes"])
+
+  AS_IF([test "x${ac_cv_libevent}" = "xyes"],[
+    save_LIBS="${LIBS}"
+    LIBS="${LIBS} ${LTLIBEVENT}"
+    AC_CHECK_FUNCS(event_base_new)
+    AC_CHECK_FUNCS(event_base_free)
+    AC_CHECK_FUNCS(event_base_get_method)
+    LIBS="$save_LIBS"
+  ])
+])
+
+AC_DEFUN([_PANDORA_HAVE_LIBEVENT],[
+
+  AC_ARG_ENABLE([libevent],
+    [AS_HELP_STRING([--disable-libevent],
+      [Build with libevent support @<:@default=on@:>@])],
+    [ac_enable_libevent="$enableval"],
+    [ac_enable_libevent="yes"])
+
+  _PANDORA_SEARCH_LIBEVENT
+])
+
+
+AC_DEFUN([PANDORA_HAVE_LIBEVENT],[
+  AC_REQUIRE([_PANDORA_HAVE_LIBEVENT])
+])
+
+AC_DEFUN([_PANDORA_REQUIRE_LIBEVENT],[
+  ac_enable_libevent="yes"
+  _PANDORA_SEARCH_LIBEVENT
+
+  AS_IF([test x$ac_cv_libevent = xno],[
+    PANDORA_MSG_ERROR([libevent is required for ${PACKAGE}. On Debian this can be found in libevent-dev. On RedHat this can be found in libevent-devel.])
+  ])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_LIBEVENT],[
+  AC_REQUIRE([_PANDORA_REQUIRE_LIBEVENT])
+])
+
+AC_DEFUN([PANDORA_LIBEVENT_RECENT],[
+  dnl FIXME I really wanted to check for existence of EVHTTP_REQ_DELETE, 
+  dnl but autoconf gods were not favorable to me, so the below is all I got
+  AC_CACHE_CHECK([if libevent is recent enough],
+    [pandora_cv_libevent_recent],
+    [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+#include <event2/event.h>
+#include <event2/http.h>
+    ]])],
+    [pandora_cv_libevent_recent=yes],
+    [pandora_cv_libevent_recent=no])])
+])
\ No newline at end of file

=== modified file 'plugin/json_server/plugin.ac'
--- plugin/json_server/plugin.ac	2012-10-19 03:12:41 +0000
+++ plugin/json_server/plugin.ac	2013-02-06 08:17:22 +0000
@@ -1,3 +1,9 @@
-AX_LIBEVENT2
-AS_IF([test "$ax_cv_libevent2" = "no"],
+PANDORA_HAVE_LIBEVENT
+
+AS_IF([test "x$ac_cv_libevent" = "xno"],
+  AC_MSG_WARN([libevent not found: not building json_server.]))
+
+PANDORA_LIBEVENT_RECENT
+
+AS_IF([test "$pandora_cv_libevent_recent" = "no"],
   AC_MSG_WARN([Your version of libevent is too old. json_server requires v 2.0 or newer: not building json_server.]))

=== modified file 'plugin/json_server/plugin.ini'
--- plugin/json_server/plugin.ini	2012-10-19 03:12:41 +0000
+++ plugin/json_server/plugin.ini	2013-02-06 08:17:22 +0000
@@ -29,5 +29,5 @@
   json/json_reader.cpp
   json/json_value.cpp
   json/json_writer.cpp
-build_conditional="x${ax_cv_libevent2}" = "xyes" -a "x${ac_cv_libcurl}" = "xyes"
-ldflags=${LIBEVENT2_LDFLAGS}
+build_conditional="x${ac_cv_libevent}" = "xyes" -a "x$pandora_cv_libevent_recent" = "xyes" -a "x${ac_cv_libcurl}" = "xyes"
+ldflags=${LTLIBEVENT}