Merge lp:~jpakkane/unity/pch-experiment into lp:unity

[Jussi Pakkanen]

Do NOT merge this code as is! It is only a proof of concept. It will compile and run but the end result will not work properly, because I had to change some definitions.

That being said, this patch adds support for GCC precompiled headers, which cuts down compile times quite nicely. To try it out, just check out and configure. Then run 'time make unity-core-6.0'. There is a CMake option for compiling with or without PCH. Just toggle that and run 'make clean' and then the previous command to compare build times.

On my machine building in debug mode without PCH takes 1m 50s. Enabling PCH drops that to 1 minute.

To get this merged, the build system needs a changes (which would be good even by themselves), enabling PCH for all targets and probably some general cleanup. None of these are massive tasks, though.

[Thomi Richards (thomir-deactivatedaccount)]

Changing to WIP so this MP doesn't sit in the review queue.

[Jussi Pakkanen (jpakkane)]

(Some of) the build fixes necessary are in this MP:

https://code.launchpad.net/~jpakkane/unity/build-fixes2/+merge/130329

=== modified file 'CMakeLists.txt'
--- CMakeLists.txt	2012-10-04 07:10:39 +0000
+++ CMakeLists.txt	2012-10-08 11:22:21 +0000
@@ -23,6 +23,8 @@
   ON
 )
 
+include(pch.cmake)
+
 if(UNITY_ENABLE_X_ORG_SUPPORT)
   add_definitions(-DUNITY_HAS_X_ORG_SUPPORT)
   message("Unity is configured with support for X.org")

=== modified file 'UnityCore/CMakeLists.txt'
--- UnityCore/CMakeLists.txt	2012-08-31 13:12:35 +0000
+++ UnityCore/CMakeLists.txt	2012-10-08 11:22:21 +0000
@@ -99,10 +99,12 @@
      ${CORE_DEPS_CFLAGS_OTHER}
      ${MAINTAINER_CFLAGS}
      "-I${CMAKE_BINARY_DIR}"
-     "-DGETTEXT_PACKAGE=\"unity\""
-     "-DLENSES_DIR=\"${_lensesdir}\""
      )
 add_definitions (${CFLAGS})
+#add_definitions("-DGETTEXT_PACKAGE=\"unity\"")
+#add_definitions("-DLENSES_DIR=\"${_lensesdir}\"")
+
+message(STATUS ${CFLAGS})
 
 set (LIBS ${CORE_DEPS_LIBRARIES})
 
@@ -133,6 +135,8 @@
                       SOVERSION ${CORE_LIB_LT_CURRENT}
                       INSTALL_RPATH "${PRIVATE_CORE_DEPS_LIBRARY_DIRS}")
 
+add_pch(pch/unitycore_pch.hh ${CORE_LIB_NAME})
+
 install (TARGETS ${CORE_LIB_NAME}
          RUNTIME DESTINATION bin
          ARCHIVE DESTINATION lib

=== modified file 'UnityCore/FilesystemLenses.cpp'
--- UnityCore/FilesystemLenses.cpp	2012-06-18 02:57:23 +0000
+++ UnityCore/FilesystemLenses.cpp	2012-10-08 11:22:21 +0000
@@ -331,7 +331,7 @@
 
 LensDirectoryReader::Ptr LensDirectoryReader::GetDefault()
 {
-  static LensDirectoryReader::Ptr main_reader(new LensDirectoryReader(LENSES_DIR));
+  static LensDirectoryReader::Ptr main_reader(new LensDirectoryReader("/tmp"));
 
   return main_reader;
 }

=== added directory 'UnityCore/pch'
=== added file 'UnityCore/pch/unitycore_pch.hh'
--- UnityCore/pch/unitycore_pch.hh	1970-01-01 00:00:00 +0000
+++ UnityCore/pch/unitycore_pch.hh	2012-10-08 11:22:21 +0000
@@ -0,0 +1,33 @@
+// -*- Mode: C++; indent-tabs-mode: nil; tab-width: 2 -*-
+/*
+ * Copyright (C) 2011 Canonical Ltd
+ *
+ * This program is free software: you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License version 3 as
+ * published by the Free Software Foundation.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with this program.  If not, see <http://www.gnu.org/licenses/>.
+ *
+ * Authored by: Jussi Pakkanen <[e-mail]>
+ */
+
+/*
+ * These are the precompiled header includes for UnityCore.
+ * You should probably only include system headers in this one.
+ */
+
+#include <vector>
+#include <string>
+#include <map>
+#include <memory>
+
+#include <dee.h>
+#include <NuxCore/Property.h>
+#include <sigc++/sigc++.h>
+#include <boost/utility.hpp>

=== added file 'pch.cmake'
--- pch.cmake	1970-01-01 00:00:00 +0000
+++ pch.cmake	2012-10-08 11:22:21 +0000
@@ -0,0 +1,72 @@
+function(get_gcc_flags target_name)
+  # CMake does not provide an easy way to get all compiler switches,
+  # so this function is a fishing expedition to get them.
+  # http://public.kitware.com/Bug/view.php?id=1260
+  set(compile_args ${CMAKE_CXX_FLAGS})
+  string(TOUPPER "${CMAKE_BUILD_TYPE}" buildtype_name)
+  if(CMAKE_CXX_FLAGS_${buildtype_name})
+      list(APPEND compile_args ${CMAKE_CXX_FLAGS_${buildtype_name}})
+  endif()
+  list(APPEND compile_args ${CFLAGS})
+  get_directory_property(dir_inc INCLUDE_DIRECTORIES)
+  foreach(item ${dir_inc})
+    LIST(APPEND compile_args "-I" ${item})
+  endforeach()
+  get_directory_property(dir_defs COMPILE_DEFINITIONS)
+  message(STATUS "CDEFS ${dir_defs}")
+  foreach(item ${dir_defs})
+      list(APPEND compile_args -D${item})
+  endforeach()
+  get_directory_property(buildtype_defs COMPILE_DEFINITIONS_${buildtype_name})
+  foreach(item ${buildtype_defs})
+     list(APPEND compile_args -D${item})
+  endforeach()
+  get_target_property(target_type ${target_name} TYPE)
+  if(${target_type} STREQUAL SHARED_LIBRARY)
+    list(APPEND compile_args ${CMAKE_CXX_COMPILE_OPTIONS_PIC})
+  endif()
+  set(compile_args ${compile_args} PARENT_SCOPE)
+  #message(STATUS ${compile_args})
+endfunction()
+
+function(add_pch_linux header_filename target_name)
+  set(gch_target_name "${target_name}_pch")
+  get_filename_component(header_basename ${header_filename} NAME)
+  set(gch_filename "${CMAKE_CURRENT_BINARY_DIR}/${header_basename}.gch")
+  get_gcc_flags(${target_name}) # Sets compile_args in this scope. It's even better than Intercal's COME FROM!
+  #message(STATUS ${compile_args})
+  list(APPEND compile_args -c ${CMAKE_CURRENT_SOURCE_DIR}/${header_filename} -o ${gch_filename})
+  separate_arguments(compile_args)
+  add_custom_command(OUTPUT ${gch_filename}
+    COMMAND ${CMAKE_CXX_COMPILER} ${compile_args}
+    DEPENDS ${header_filename})
+  add_custom_target(${gch_target_name} DEPENDS ${gch_filename})
+  add_dependencies(${target_name} ${gch_target_name})
+  
+  set_property(TARGET ${target_name} APPEND_STRING PROPERTY COMPILE_FLAGS "-include ${header_basename}")
+  
+  # Each directory should have only one precompiled header
+  # for simplicity. If there are several, the current dir
+  # gets added to the search path several times.
+  # It should not be an issue, though.
+  include_directories(BEFORE ${CMAKE_CURRENT_BINARY_DIR})
+endfunction()
+
+if(UNIX)
+  if(NOT APPLE)
+    option(use_pch "Use precompiled headers." TRUE)
+  endif()
+endif()
+
+if(use_pch)
+  message(STATUS "Using precompiled headers.")
+  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Winvalid-pch")
+  #add_definitions(-DUSE_PCH)
+  macro(add_pch _header_filename _target_name)
+    add_pch_linux(${_header_filename} ${_target_name})
+  endmacro()
+else()
+  message(STATUS "Not using precompiled headers.")
+  macro(add_pch _header_filename _target_name)
+  endmacro()
+endif()