Merge lp:~jpakkane/unity-lens-video/coverage into lp:~stolowski/unity-lens-video/vala-rewrite

[Jussi Pakkanen]

Coverage support.

Coverage support.

[Paweł Stołowski (stolowski)]

Please also update sources in tests/unit/Makefile.am to include all vala files from src/ (except for config.vala, main.vala and mocked class(es)). That way coverage report will be more accurate.

Apart from that it works fine.

review: Needs Fixing

[lp:~jpakkane/unity-lens-video/coverage]

156. By Jussi Pakkanen on 2013-02-19

Merged changes.

157. By Jussi Pakkanen on 2013-02-19

Added vala sources to list so they show up in coverage measurements.

[Paweł Stołowski (stolowski)]

LGTM. +1

review: Approve

=== modified file 'Makefile.am'
--- Makefile.am	2012-11-22 12:23:14 +0000
+++ Makefile.am	2013-02-19 12:24:23 +0000
@@ -1,3 +1,5 @@
 SUBDIRS = src po tests/unit vapi data
 
 DISTCHECK_CONFIGURE_FLAGS = --enable-localinstall
+
+include $(top_srcdir)/Makefile.am.coverage

=== added file 'Makefile.am.coverage'
--- Makefile.am.coverage	1970-01-01 00:00:00 +0000
+++ Makefile.am.coverage	2013-02-19 12:24:23 +0000
@@ -0,0 +1,48 @@
+
+# Coverage targets
+
+.PHONY: clean-gcno clean-gcda \
+	coverage-html generate-coverage-html clean-coverage-html \
+	coverage-gcovr generate-coverage-gcovr clean-coverage-gcovr
+
+clean-local: clean-gcno clean-coverage-html clean-coverage-gcovr
+
+if HAVE_GCOV
+
+clean-gcno:
+	@echo Removing old coverage instrumentation
+	-find -name '*.gcno' -print | xargs -r rm
+
+clean-gcda:
+	@echo Removing old coverage results
+	-find -name '*.gcda' -print | xargs -r rm
+  
+coverage-html: clean-gcda
+	-$(MAKE) $(AM_MAKEFLAGS) -k check
+	$(MAKE) $(AM_MAKEFLAGS) generate-coverage-html
+  
+generate-coverage-html:
+	@echo Collecting coverage data
+	$(LCOV) --directory $(top_builddir) --capture --output-file coverage.info --no-checksum --compat-libtool
+	LANG=C $(GENHTML) --prefix $(top_builddir) --output-directory coveragereport --title "Code Coverage" --legend --show-details coverage.info
+  
+clean-coverage-html: clean-gcda
+	-$(LCOV) --directory $(top_builddir) -z
+	-rm -rf coverage.info coveragereport
+
+if HAVE_GCOVR
+
+coverage-gcovr: clean-gcda
+	-$(MAKE) $(AM_MAKEFLAGS) -k check
+	$(MAKE) $(AM_MAKEFLAGS) generate-coverage-gcovr
+	
+generate-coverage-gcovr:
+	@echo Generating coverage GCOVR report
+	$(GCOVR) -x -r $(top_builddir) -o $(top_builddir)/coverage.xml
+	
+clean-coverage-gcovr: clean-gcda
+	-rm -rf $(top_builddir)/coverage.xml
+
+endif # HAVE_GCOVR
+
+endif # HAVE_GCOV

=== modified file 'configure.ac'
--- configure.ac	2013-02-18 11:14:01 +0000
+++ configure.ac	2013-02-19 12:24:23 +0000
@@ -51,6 +51,17 @@
 INTLTOOL_LENS_RULE='%.lens: %.lens.in $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
 AC_SUBST(INTLTOOL_LENS_RULE)
 
+###########################
+# gcov coverage reporting
+###########################
+m4_include([m4/gcov.m4])
+AC_TDD_GCOV
+AM_CONDITIONAL([HAVE_GCOV], [test "x$ac_cv_check_gcov" = xyes])
+AM_CONDITIONAL([HAVE_LCOV], [test "x$ac_cv_check_lcov" = xyes])
+AM_CONDITIONAL([HAVE_GCOVR], [test "x$ac_cv_check_gcovr" = xyes])
+AC_SUBST(COVERAGE_CFLAGS)
+AC_SUBST(COVERAGE_LDFLAGS)
+
 #####################################################
 # Check for module and library dependancies
 #####################################################
@@ -189,4 +200,9 @@
   Extra ValaFlags : ${CPPFLAGS} $MAINTAINER_VALAFLAGS
 
   Lenses Directory: ${LENSESDIR}
+
+  Testing
+    Headless tests     : ${enable_headless_tests}
+    Coverage reporting : ${use_gcov}
+
 ])

=== added directory 'm4'
=== added file 'm4/gcov.m4'
--- m4/gcov.m4	1970-01-01 00:00:00 +0000
+++ m4/gcov.m4	2013-02-19 12:24:23 +0000
@@ -0,0 +1,86 @@
+# Checks for existence of coverage tools:
+#  * gcov
+#  * lcov
+#  * genhtml
+#  * gcovr
+# 
+# Sets ac_cv_check_gcov to yes if tooling is present
+# and reports the executables to the variables LCOV, GCOVR and GENHTML.
+AC_DEFUN([AC_TDD_GCOV],
+[
+  AC_ARG_ENABLE(gcov,
+  AS_HELP_STRING([--enable-gcov],
+		 [enable coverage testing with gcov]),
+  [use_gcov=$enableval], [use_gcov=no])
+
+  if test "x$use_gcov" = "xyes"; then
+  # we need gcc:
+  if test "$GCC" != "yes"; then
+    AC_MSG_ERROR([GCC is required for --enable-gcov])
+  fi
+
+  # Check if ccache is being used
+  AC_CHECK_PROG(SHTOOL, shtool, shtool)
+  case `$SHTOOL path $CC` in
+    *ccache*[)] gcc_ccache=yes;;
+    *[)] gcc_ccache=no;;
+  esac
+
+  if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
+    AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
+  fi
+
+  lcov_version_list="1.6 1.7 1.8 1.9"
+  AC_CHECK_PROG(LCOV, lcov, lcov)
+  AC_CHECK_PROG(GENHTML, genhtml, genhtml)
+
+  if test "$LCOV"; then
+    AC_CACHE_CHECK([for lcov version], glib_cv_lcov_version, [
+      glib_cv_lcov_version=invalid
+      lcov_version=`$LCOV -v 2>/dev/null | $SED -e 's/^.* //'`
+      for lcov_check_version in $lcov_version_list; do
+        if test "$lcov_version" = "$lcov_check_version"; then
+          glib_cv_lcov_version="$lcov_check_version (ok)"
+        fi
+      done
+    ])
+  else
+    lcov_msg="To enable code coverage reporting you must have one of the following lcov versions installed: $lcov_version_list"
+    AC_MSG_ERROR([$lcov_msg])
+  fi
+
+  case $glib_cv_lcov_version in
+    ""|invalid[)]
+      lcov_msg="You must have one of the following versions of lcov: $lcov_version_list (found: $lcov_version)."
+      AC_MSG_ERROR([$lcov_msg])
+      LCOV="exit 0;"
+      ;;
+  esac
+
+  if test -z "$GENHTML"; then
+    AC_MSG_ERROR([Could not find genhtml from the lcov package])
+  fi
+
+  ac_cv_check_gcov=yes
+  ac_cv_check_lcov=yes
+
+  # Remove all optimization flags from CFLAGS
+  changequote({,})
+  CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
+  changequote([,])
+
+  # Add the special gcc flags
+  COVERAGE_CFLAGS="-O0 -fprofile-arcs -ftest-coverage"
+  COVERAGE_CXXFLAGS="-O0 -fprofile-arcs -ftest-coverage"	
+  COVERAGE_LDFLAGS="-lgcov"
+
+  # Check availability of gcovr
+  AC_CHECK_PROG(GCOVR, gcovr, gcovr)
+  if test -z "$GCOVR"; then
+    ac_cv_check_gcovr=no
+  else
+    ac_cv_check_gcovr=yes
+  fi
+
+fi
+]) # AC_TDD_GCOV

=== modified file 'src/Makefile.am'
--- src/Makefile.am	2013-02-18 11:14:01 +0000
+++ src/Makefile.am	2013-02-19 12:24:23 +0000
@@ -5,6 +5,9 @@
 
 DATADIR = $(datadir)
 
+AM_CPPFLAGS = $(COVERAGE_CFLAGS)
+AM_LDFLAGS = $(COVERAGE_LDFLAGS)
+
 pkglibexec_PROGRAMS = \
 	unity-video-lens-daemon \
 	unity-scope-video-remote \

=== modified file 'tests/unit/Makefile.am'
--- tests/unit/Makefile.am	2012-11-27 12:17:56 +0000
+++ tests/unit/Makefile.am	2013-02-19 12:24:23 +0000
@@ -17,6 +17,8 @@
 	  --pkg json-glib-1.0 \
 	  --pkg glib-2.0 \
 	  --pkg zeitgeist-1.0 \
+	  --pkg libsoup-gnome-2.4 \
+	  --pkg libsoup-2.4 \
 	  --vapidir $(srcdir) \
 	  --vapidir $(top_srcdir)/vapi \
 	  --target-glib=2.26 \
@@ -31,8 +33,11 @@
   -I$(srcdir) \
   -I$(top_srcdir)/src \
   -DGETTEXT_PACKAGE=\"$(GETTEXT_PACKAGE)\" \
+  $(COVERAGE_CFLAGS) \
   $(NULL)
 
+AM_LDFLAGS = $(COVERAGE_LDFLAGS)
+
 if !ENABLE_C_WARNINGS
   AM_CPPFLAGS += -w
 endif
@@ -41,23 +46,26 @@
 	test-locate.vala \
 	thumbnailer-mock.vala \
 	config-tests.vala \
-	../../src/locate.vala \
-	../../src/utils.vala \
-	../../src/video-file.vala \
+	$(top_srcdir)/src/locate.vala \
+	$(top_srcdir)/src/utils.vala \
+	$(top_srcdir)/src/video-file.vala \
 	$(NULL)
 
 test_utils_VALASOURCES = \
 	test-utils.vala \
 	config-tests.vala \
-	../../src/utils.vala \
+	$(top_srcdir)/src/utils.vala \
 	$(NULL)
 
 test_ubuntu_video_search_VALASOURCES = \
 	test-ubuntu-video-search.vala \
 	config-tests.vala \
-	../../src/remote-scope-globals.vala \
-	../../src/ubuntu-video-search.vala \
-	../../src/video-file.vala \
+	$(top_srcdir)/src/remote-scope-globals.vala \
+	$(top_srcdir)/src/ubuntu-video-search.vala \
+	$(top_srcdir)/src/video-file.vala \
+	$(top_srcdir)/src/remote-scope.vala \
+	$(top_srcdir)/src/remote-uri.vala \
+	$(top_srcdir)/src/utils.vala \
 	$(NULL)
 
 nodist_test_locate_SOURCES = $(test_locate_VALASOURCES:.vala=.c)

=== modified file 'tests/unit/config-tests.vala.in'
--- tests/unit/config-tests.vala.in	2012-11-27 12:17:56 +0000
+++ tests/unit/config-tests.vala.in	2013-02-19 12:24:23 +0000
@@ -2,4 +2,5 @@
   const string TESTDATADIR = "@abs_top_srcdir@/tests/unit/data";
   const string LOCALEDIR = "@DATADIR@/locale";
   const string PACKAGE = "@PACKAGE@";
+  const string VERSION = "@VERSION@";
 }