Merge lp:~johannr/meshbuilder/cmake into lp:meshbuilder

[Johannes Ring]

CMake has good support for Qt and OpenSceneGraph applications. This branch moves MeshBuilder to CMake. Other benefits for moving to CMake are:

* Can use find_package(dolfin) instead of pkgconfig
* One less build system to be familiar with
* Out-of-source builds
* CPack for generating binaries

This branch also collects source code under a common subdirectory "src" and adds a man page.

The build steps should be familiar:

mkdir build
cd build
cmake -DCMAKE_INSTALL_PREFIX:PATH=/foo/bar ..
make
make install

[Benjamin Kehlet (benjamik)]

Nice!

review: Approve

[lp:~johannr/meshbuilder/cmake]

154. By Benjamin Kehlet on 2011-05-27

Replace qmake with CMake.

=== added file 'CMakeLists.txt'
--- CMakeLists.txt	1970-01-01 00:00:00 +0000
+++ CMakeLists.txt	2011-05-23 14:26:27 +0000
@@ -0,0 +1,30 @@
+# require 
+cmake_minimum_required(VERSION 2.8.0)
+
+# project name
+project(MESHBUILDER)
+
+# project version
+set(MESHBUILDER_VERSION_MAJOR 0)
+set(MESHBUILDER_VERSION_MINOR 2)
+set(MESHBUILDER_VERSION_PATCH 0)
+
+add_definitions(
+  -DMB_VERSION_MAJOR="${MESHBUILDER_VERSION_MAJOR}"
+  -DMB_VERSION_MINOR="${MESHBUILDER_VERSION_MINOR}"
+  -DMB_VERSION_PATCH="${MESHBUILDER_VERSION_PATCH}"
+  -DQT_CLEAN_NAMESPACE
+  )
+
+# find required packages
+find_package(Qt4 REQUIRED)
+find_package(OpenSceneGraph REQUIRED osgGA osgViewer osgFX osgUtil)
+find_package(OpenGL REQUIRED)
+find_package(dolfin REQUIRED
+  HINTS ${DOLFIN_DIR}/share/dolfin/cmake $ENV{DOLFIN_DIR}/share/dolfin/cmake)
+
+# meshbuilder executable
+add_subdirectory(src)
+
+# documentation, manual pages
+add_subdirectory(doc)

=== added directory 'doc'
=== added file 'doc/CMakeLists.txt'
--- doc/CMakeLists.txt	1970-01-01 00:00:00 +0000
+++ doc/CMakeLists.txt	2011-05-23 14:26:27 +0000
@@ -0,0 +1,17 @@
+find_program(GZIP_EXECUTABLE NAMES gzip)
+
+set(MESHBUILDER_MANFILE "${CMAKE_CURRENT_SOURCE_DIR}/man/man1/meshbuilder.1")
+set(MESHBUILDER_GZIP_MANFILE "${CMAKE_CURRENT_BINARY_DIR}/meshbuilder.1.gz")
+add_custom_command(OUTPUT ${MESHBUILDER_GZIP_MANFILE}
+  COMMAND ${GZIP_EXECUTABLE} -c -f ${MESHBUILDER_MANFILE} > ${MESHBUILDER_GZIP_MANFILE}
+  DEPENDS ${MESHBUILDER_MANFILE}
+  WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
+  )
+
+add_custom_target(man ALL DEPENDS ${MESHBUILDER_GZIP_MANFILE}
+  WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
+
+# install meshbuilder executable
+install(FILES ${MESHBUILDER_GZIP_MANFILE}
+  DESTINATION share/man/man1
+  COMPONENT RuntimeExecutables)

=== added directory 'doc/man'
=== added directory 'doc/man/man1'
=== added file 'doc/man/man1/meshbuilder.1'
--- doc/man/man1/meshbuilder.1	1970-01-01 00:00:00 +0000
+++ doc/man/man1/meshbuilder.1	2011-05-23 14:26:27 +0000
@@ -0,0 +1,19 @@
+.TH MESHBUILDER 1
+.SH NAME
+meshbuilder \- Mesh builder for DOLFIN
+.SH SYNOPSIS
+.B meshbuilder
+.SH DESCRIPTION
+MeshBuilder is a tool for building meshes for DOLFIN. With MeshBuilder
+you can set integer meshfunctions on DOLFIN meshes, on vertices, edges,
+and faces. These can be saved and loaded. You also use MeshBuilder to
+create screenshots and one can look at the boundary mesh of a mesh (or a
+2D mesh directly). MeshBuilder is provided by FEniCS.
+.SH OPTIONS
+MeshBuilder does not offer command-line options of its own; at present
+one cannot open mesh files from the command-line. As a Qt application it
+supports Qt options; please see:
+
+http://doc.trolltech.com/4.2/qapplication.html#QApplication
+.SH AUTHOR
+This manual page was written by Johannes Ring <[e-mail]>.

=== removed file 'meshbuilder.pro'
--- meshbuilder.pro	2011-05-16 23:02:33 +0000
+++ meshbuilder.pro	1970-01-01 00:00:00 +0000
@@ -1,126 +0,0 @@
-# -*- makefile -*-
-
-TEMPLATE = app
-TARGET   = meshbuilder
-
-OBJECTS_DIR = build
-MOC_DIR = build
-UI_DIR = build
-
-CONFIG += debug
-
-# The following look like a contradiction, but warn_on enables 
-# strictwarnings (the -W option) as well, which leads to 
-# a load of warnings from the Dolfin headers.
-CONFIG += warn_off
-QMAKE_CXXFLAGS += -Wall
-
-QT += opengl xml
-
-DEFINES += LINUX
-DEFINES += QT_CLEAN_NAMESPACE
-#DEFINES += QT_NO_DEBUG
-
-RESOURCES = resources.qrc
-
-# Main mode options.
-
-VER_MAJ = 0
-VER_MIN = 2
-VER_PAT = 0
-
-DEFINES += MB_VERSION_MAJOR=$$VER_MAJ
-DEFINES += MB_VERSION_MINOR=$$VER_MIN
-DEFINES += MB_VERSION_PATCH=$$VER_PAT
-
-FORMS   = \
-	gui/ColorButton.ui \
-	gui/FloatSlider.ui \
-	gui/Colormap.ui \
-	gui/ApplicationWindow.ui
-
-HEADERS = \
-	base/ObjectState.h \
-	util/QtUtil.h \
-	util/SimResState.h \
-	osgQt/AdapterWidget.h \
-	osgQt/TrackballManipulator.h \
-	osgQt/RenderArea.h \
-	scenegraph/OsgTransformObject.h \
-	scenegraph/OsgDrawableObject.h \
-	scenegraph/OsgDrawableObjectConnector.h \
-	scenegraph/OsgMeshObject.h \
-	scenegraph/OsgDolfinObject.h \
-	gui/ColorButton.h \
-	gui/FloatSlider.h \
-	gui/Colormap.h \
-	gui/Context.h \
-	gui/MaterialSettings.h \
-	gui/TransformSettings.h \
-	gui/SimResSettings.h \
-	gui/DolfinEventHandler.h \
-	gui/Viewer.h \
-	gui/ApplicationWindow.h \
-	gui/Viewer_2D.h \
-	gui/Scene_2D.h \
-	gui/EntityInterface_2D.h \
-	gui/Vertex_2D.h \
-	gui/Edge_2D.h \
-	gui/Axes_2D.h \
-	gui/VisualizationDialog_2D.h \
-	gui/ViewerSettingsDialog.h \
-	gui/ClipPlanesDialog.h \
-	gui/TransformationsDialog.h \
-	gui/VisualizationDialog.h \
-	gui/DrawSettingsDialog.h \
-	gui/MeshFunctionsToolbar.h \
-  gui/ViewerInterface.h \
-  gui/DolfinObject.h
-
-SOURCES = \
-	util/QtUtil.cpp \
-	util/SimResState.cpp \
-	osgQt/AdapterWidget.cpp \
-	osgQt/TrackballManipulator.cpp \
-	osgQt/RenderArea.cpp \
-	scenegraph/OsgTransformObject.cpp \
-	scenegraph/OsgDrawableObject.cpp \
-	scenegraph/OsgMeshObject.cpp \
-	scenegraph/OsgDolfinObject.cpp \
-	gui/ColorButton.cpp \
-	gui/FloatSlider.cpp \
-	gui/Colormap.cpp \
-	gui/Context.cpp \
-	gui/MaterialSettings.cpp \
-	gui/TransformSettings.cpp \
-	gui/SimResSettings.cpp \
-	gui/DolfinEventHandler.cpp \
-	gui/Viewer.cpp \
-	gui/ApplicationWindow.cpp \
-	gui/Viewer_2D.cpp \
-	gui/Scene_2D.cpp \
-	gui/Vertex_2D.cpp \
-	gui/Edge_2D.cpp \
-	gui/Axes_2D.cpp \
-	gui/VisualizationDialog_2D.cpp \
-	gui/ViewerSettingsDialog.cpp \
-	gui/ClipPlanesDialog.cpp \
-	gui/TransformationsDialog.cpp \
-	gui/VisualizationDialog.cpp \
-	gui/DrawSettingsDialog.cpp \
-	gui/MeshFunctionsToolbar.cpp \
-  gui/DolfinObject.cpp \
-	main.cpp 
-
-
-# Sub directories
-DEPENDPATH += base gui scenegraph util osgQt
-
-# Open scene graph flags
-QMAKE_CXXFLAGS += $$system(pkg-config --cflags openscenegraph)
-LIBS += $$system(pkg-config --libs openscenegraph)
-
-# DOLFIN flags
-QMAKE_CXXFLAGS += $$system(pkg-config --cflags dolfin)
-LIBS += $$system(pkg-config --libs dolfin)
-

=== added directory 'src'
=== added file 'src/CMakeLists.txt'
--- src/CMakeLists.txt	1970-01-01 00:00:00 +0000
+++ src/CMakeLists.txt	2011-05-23 14:26:27 +0000
@@ -0,0 +1,145 @@
+# set include directories
+include_directories(
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${OPENSCENEGRAPH_INCLUDE_DIRS}
+  ${OPENGL_INCLUDE_DIR}
+  ${DOLFIN_INCLUDE_DIRS}
+  ${DOLFIN_3RD_PARTY_INCLUDE_DIRS}
+  )
+
+add_definitions(${DOLFIN_CXX_DEFINITIONS})
+
+# add Qt modules here, the include will setup QT_LIBRARIES
+set(QT_USE_QTOPENGL TRUE)
+set(QT_USE_QTXML TRUE)
+
+include(${QT_USE_FILE})
+
+# .cpp sources
+set(MESHBUILDER_SRCS_CXX
+  util/QtUtil.cpp
+  util/SimResState.cpp
+
+  osgQt/AdapterWidget.cpp
+  osgQt/TrackballManipulator.cpp
+  osgQt/RenderArea.cpp
+
+  scenegraph/OsgTransformObject.cpp
+  scenegraph/OsgDrawableObject.cpp
+  scenegraph/OsgMeshObject.cpp
+  scenegraph/OsgDolfinObject.cpp
+
+  gui/ColorButton.cpp
+  gui/FloatSlider.cpp
+  gui/Colormap.cpp
+  gui/Context.cpp
+  gui/MaterialSettings.cpp
+  gui/TransformSettings.cpp
+  gui/SimResSettings.cpp
+  gui/DolfinEventHandler.cpp
+  gui/Viewer.cpp
+  gui/ApplicationWindow.cpp
+  gui/Viewer_2D.cpp
+  gui/Scene_2D.cpp
+  gui/Vertex_2D.cpp
+  gui/Edge_2D.cpp
+  gui/Axes_2D.cpp
+  gui/VisualizationDialog_2D.cpp
+  gui/ViewerSettingsDialog.cpp
+  gui/ClipPlanesDialog.cpp
+  gui/TransformationsDialog.cpp
+  gui/VisualizationDialog.cpp
+  gui/DrawSettingsDialog.cpp
+  gui/MeshFunctionsToolbar.cpp
+  gui/DolfinObject.cpp
+  
+  main.cpp
+  )
+
+# files which need to be moc'd by Qt
+set(MESHBUILDER_MOC_SRCS
+  #base/ObjectState.h
+
+  #util/QtUtil.h
+  util/SimResState.h
+
+  osgQt/AdapterWidget.h
+  #osgQt/TrackballManipulator.h
+  osgQt/RenderArea.h
+
+  #scenegraph/OsgTransformObject.h
+  #scenegraph/OsgDrawableObject.h
+  scenegraph/OsgDrawableObjectConnector.h
+  #scenegraph/OsgMeshObject.h
+  #scenegraph/OsgDolfinObject.h
+
+  gui/ColorButton.h
+  gui/FloatSlider.h
+  gui/Colormap.h
+  gui/Context.h
+  gui/MaterialSettings.h
+  gui/TransformSettings.h
+  gui/SimResSettings.h
+  #gui/DolfinEventHandler.h
+  gui/Viewer.h
+  gui/ApplicationWindow.h
+  gui/Viewer_2D.h
+  gui/Scene_2D.h
+  gui/EntityInterface_2D.h
+  #gui/Vertex_2D.h
+  #gui/Edge_2D.h
+  gui/Axes_2D.h
+  gui/VisualizationDialog_2D.h
+  gui/ViewerSettingsDialog.h
+  gui/ClipPlanesDialog.h
+  gui/TransformationsDialog.h
+  gui/VisualizationDialog.h
+  gui/DrawSettingsDialog.h
+  gui/MeshFunctionsToolbar.h
+  gui/ViewerInterface.h
+  gui/DolfinObject.h
+  )
+
+# ui files
+set(MESHBUILDER_UIS
+  gui/ColorButton.ui
+  gui/FloatSlider.ui
+  gui/Colormap.ui
+  gui/ApplicationWindow.ui
+  )
+
+# resource files
+set(MESHBUILDER_RCS
+  resources.qrc
+  )
+
+# build ui_XXX files from the XML-style .ui files
+qt4_wrap_ui(MESHBUILDER_SRCS_CXX ${MESHBUILDER_UIS})
+
+# this moc's the above variable and appends to the cpp sources
+qt4_wrap_cpp(MESHBUILDER_SRCS_CXX ${MESHBUILDER_MOC_SRCS})
+
+# this runs rcc on the resources and appends to the cpp sources
+qt4_add_resources(MESHBUILDER_SRCS_CXX ${MESHBUILDER_RCS})
+
+# create the meshbuilder executable
+if (UNIX)
+  add_executable(meshbuilder ${MESHBUILDER_SRCS_CXX})
+elseif (APPLE)
+  add_executable(meshbuilder MACOSX_BUNDLE ${MESHBUILDER_SRCS_CXX})
+elseif (WIN32)
+  add_executable(meshbuilder WIN32 ${MESHBUILDER_SRCS_CXX})
+endif()
+
+# link against required libraries
+target_link_libraries(meshbuilder
+  ${QT_LIBRARIES}
+  ${OPENSCENEGRAPH_LIBRARIES}
+  ${OPENGL_LIBRARIES}
+  ${DOLFIN_LIBRARIES}
+  ${DOLFIN_3RD_PARTY_LIBRARIES}
+  )
+
+# install meshbuilder executable
+install(TARGETS meshbuilder DESTINATION bin COMPONENT RuntimeExecutables)

=== renamed directory 'base' => 'src/base'
=== renamed directory 'gui' => 'src/gui'
=== modified file 'src/gui/ApplicationWindow.cpp'
--- gui/ApplicationWindow.cpp	2011-02-11 05:51:14 +0000
+++ src/gui/ApplicationWindow.cpp	2011-05-23 14:26:27 +0000
@@ -5,7 +5,7 @@
 #include <gui/MeshFunctionsToolbar.h>
 #include <gui/ViewerInterface.h>
 
-#include <build/ui_ApplicationWindow.h>
+#include <ui_ApplicationWindow.h>
 
 #include <QFileDialog>
 #include <QApplication>

=== modified file 'src/gui/ApplicationWindow.h'
--- gui/ApplicationWindow.h	2011-02-11 05:51:14 +0000
+++ src/gui/ApplicationWindow.h	2011-05-23 14:26:27 +0000
@@ -5,7 +5,7 @@
 #include <gui/Context.h>
 #include <gui/Viewer.h>
 #include <util/SimResState.h>
-#include <build/ui_ApplicationWindow.h>
+#include <ui_ApplicationWindow.h>
 
 #include <QMainWindow>
 

=== modified file 'src/gui/ColorButton.cpp'
--- gui/ColorButton.cpp	2010-03-27 14:26:04 +0000
+++ src/gui/ColorButton.cpp	2011-05-23 14:26:27 +0000
@@ -1,5 +1,5 @@
 #include <gui/ColorButton.h>
-#include <build/ui_ColorButton.h>
+#include <ui_ColorButton.h>
 
 #include <QColorDialog>
 #include <QPushButton>

=== modified file 'src/gui/Colormap.cpp'
--- gui/Colormap.cpp	2010-03-26 15:36:55 +0000
+++ src/gui/Colormap.cpp	2011-05-23 14:26:27 +0000
@@ -1,5 +1,5 @@
 #include <gui/Colormap.h>
-#include <build/ui_Colormap.h>
+#include <ui_Colormap.h>
 
 #include <QColorDialog>
 

=== modified file 'src/gui/FloatSlider.cpp'
--- gui/FloatSlider.cpp	2010-03-26 15:36:55 +0000
+++ src/gui/FloatSlider.cpp	2011-05-23 14:26:27 +0000
@@ -1,5 +1,5 @@
 #include <gui/FloatSlider.h>
-#include <build/ui_FloatSlider.h>
+#include <ui_FloatSlider.h>
 
 #include <QSlider>
 #include <QLineEdit>

=== renamed file 'main.cpp' => 'src/main.cpp'
=== renamed directory 'osgQt' => 'src/osgQt'
=== renamed directory 'resources' => 'src/resources'
=== renamed file 'resources.qrc' => 'src/resources.qrc'
=== renamed directory 'scenegraph' => 'src/scenegraph'
=== renamed directory 'util' => 'src/util'