Merge lp:~dpm/ubuntu-clock-app/i18n-module into lp:ubuntu-clock-app

[David Planella]

Convert the cmake rules for internationalization to a cmake module we can easily reuse for all core apps.

Convert the cmake rules for internationalization to a cmake module we can easily reuse for all core apps.

Some notes on which I'd appreciate feedback from anyone reviewing this MP:

- It'd be nice to make the configuration and merging of the .desktop file optional, for those projects which don't use .desktop files. An example is indicators, which already use their own Translations.cmake module - it'd be good if all projects could use one and only module.
- I'm tempted to assume that DESKTOP_FILE == DOMAIN to make things easier and thus make it not a required arg to the macros
- I've not figured out how to pass a COPYRIGHT_HOLDER with spaces without showing escaped spaces in the final .pot file ("\ ")

[Ubuntu Phone Apps Jenkins Bot (ubuntu-phone-apps-jenkins-bot)]

PASSED: Continuous integration, rev:149
http://91.189.93.70:8080/job/ubuntu-clock-app-ci/559/
Executed test runs:
    SUCCESS: http://91.189.93.70:8080/job/generic-mediumtests-utopic-python3/923
        deb: http://91.189.93.70:8080/job/generic-mediumtests-utopic-python3/923/artifact/work/output/*zip*/output.zip

Click here to trigger a rebuild:
http://91.189.93.70:8080/job/ubuntu-clock-app-ci/559/rebuild

review: Approve (continuous-integration)

[dobey (dobey)]

I would add an if() to check that ${ARGN} is empty and recurse over all paths if so, or just get rid of the path arguments list, and always recurse over everything.

If this makes things easier for the core apps in the short-term I think it's fine. But I don't think this is a long-term solution to fixing builds of translations. For that, I think we need to fix up intltool to behave well with cmake, and provide an Intltool.cmake.

It looks fine to me otherwise though.

review: Approve

[Nekhelesh Ramananthan (nik90)]

Is this ready to be top-approved and merged? Might need to resync with trunk to check for any code conflicts.

review: Needs Information

Unmerged revisions

149. By David Planella on 2014-10-13

Finished cmake module conversion of i18n rules

148. By David Planella on 2014-10-13

Made path to i18n source files relative to po folder

147. By David Planella on 2014-10-13

Fix to pot file variable name, ignored generated clicks from bzr

146. By David Planella on 2014-10-13

Finished conversion of i18n rules to a module

145. By David Planella on 2014-10-13

Initial move of the translations cmake rules to a cmake module

=== modified file '.bzrignore'
--- .bzrignore	2014-07-15 12:41:13 +0000
+++ .bzrignore	2014-10-13 20:01:49 +0000
@@ -1,2 +1,3 @@
 *.user
 builddir
+*.click

=== modified file 'CMakeLists.txt'
--- CMakeLists.txt	2014-09-27 10:36:56 +0000
+++ CMakeLists.txt	2014-10-13 20:01:49 +0000
@@ -1,18 +1,12 @@
 project(com.ubuntu.clock C CXX)
 cmake_minimum_required(VERSION 2.8.9)
 
-find_program(INTLTOOL_MERGE intltool-merge)
-if(NOT INTLTOOL_MERGE)
-    message(FATAL_ERROR "Could not find intltool-merge, please install the intltool package")
-endif()
-
-find_program(INTLTOOL_EXTRACT intltool-extract)
-if(NOT INTLTOOL_EXTRACT)
-    message(FATAL_ERROR "Could not find intltool-extract, please install the intltool package")
-endif()
-
-set (UBUNTU_MANIFEST_PATH "manifest.json.in" CACHE INTERNAL "Relative path to the manifest file")
-set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -fno-permissive -pedantic -Wall -Wextra")
+list(APPEND CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
+
+set(GETTEXT_PACKAGE ${CMAKE_PROJECT_NAME})
+
+set(UBUNTU_MANIFEST_PATH "manifest.json.in" CACHE INTERNAL "Relative path to the manifest file")
+set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -fno-permissive -pedantic -Wall -Wextra")
 
 find_package(Qt5Core)
 find_package(Qt5Qml)
@@ -88,22 +82,6 @@
 
 install(FILES ${URLS_FILE} DESTINATION "${CMAKE_INSTALL_DATADIR}/url-dispatcher/urls")
 
-file(GLOB_RECURSE I18N_SRC_FILES
-    RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}/po
-    *.qml *.js)
-list(APPEND I18N_SRC_FILES ${DESKTOP_FILE}.in.in.h)
-list(SORT I18N_SRC_FILES)
-
-configure_file(${DESKTOP_FILE}.in.in ${DESKTOP_FILE}.in)
-
-add_custom_target(${DESKTOP_FILE} ALL
-    COMMENT "Merging translations into ${DESKTOP_FILE}..."
-    COMMAND LC_ALL=C ${INTLTOOL_MERGE} -d -u ${CMAKE_SOURCE_DIR}/po ${DESKTOP_FILE}.in ${DESKTOP_FILE}
-)
-
-install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${DESKTOP_FILE}
-        DESTINATION ${CMAKE_INSTALL_DATADIR}/applications)
-
 add_subdirectory(app)
 add_subdirectory(backend)
 add_subdirectory(po)

=== added directory 'cmake'
=== added file 'cmake/FindIntltool.cmake'
--- cmake/FindIntltool.cmake	1970-01-01 00:00:00 +0000
+++ cmake/FindIntltool.cmake	2014-10-13 20:01:49 +0000
@@ -0,0 +1,11 @@
+# Finds the intltool program to merge and extract translations from .desktop files
+
+find_program(INTLTOOL_MERGE intltool-merge)
+if(NOT INTLTOOL_MERGE)
+    message(FATAL_ERROR "Could not find intltool-merge, please install the intltool package")
+endif()
+
+find_program(INTLTOOL_EXTRACT intltool-extract)
+if(NOT INTLTOOL_EXTRACT)
+    message(FATAL_ERROR "Could not find intltool-extract, please install the intltool package")
+endif()

=== added file 'cmake/Translations.cmake'
--- cmake/Translations.cmake	1970-01-01 00:00:00 +0000
+++ cmake/Translations.cmake	2014-10-13 20:01:49 +0000
@@ -0,0 +1,87 @@
+include(FindGettext)
+include(FindIntltool)
+
+# Builds and installs translations, compiling source .po files into binary .mo files.
+# It also merges .desktop file key translations from source .po files into a generated
+# .desktop file. It assumes a .desktop.in.in file exists at the top of the source tree
+#
+# Arguments:
+# - DOMAIN: translation domain, generally the name of the app or project.
+#           It will determine the name of the installed .mo files
+# - DESKTOP_FILE: the name portion of the desktop file to merge translations into
+macro(add_translations DOMAIN DESKTOP_FILE)
+    # Find all translations (*.po files)
+    file(GLOB PO_FILES ${CMAKE_CURRENT_SOURCE_DIR}/*.po)
+
+    # Iterate through all translations, build them and install them
+    foreach(PO_FILE ${PO_FILES})
+        get_filename_component(LANG ${PO_FILE} NAME_WE)
+        gettext_process_po_files(${LANG} ALL PO_FILES ${PO_FILE})
+        install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${LANG}.gmo
+                DESTINATION ${CMAKE_INSTALL_LOCALEDIR}/${LANG}/LC_MESSAGES
+                RENAME ${DOMAIN}.mo)
+    endforeach(PO_FILE)
+
+    # Configure the desktop file and do cmake variable substitution
+    configure_file(${CMAKE_SOURCE_DIR}/${DESKTOP_FILE}.in.in ${CMAKE_CURRENT_BINARY_DIR}/${DESKTOP_FILE}.in)
+
+    # Extract translated desktop file keys from the po files and merge them
+    # into the final desktop file
+    add_custom_target(${DESKTOP_FILE} ALL
+        COMMENT "Merging translations into ${DESKTOP_FILE}..."
+        COMMAND LC_ALL=C ${INTLTOOL_MERGE} -d -u ${CMAKE_SOURCE_DIR}/po
+            ${CMAKE_CURRENT_BINARY_DIR}/${DESKTOP_FILE}.in
+            ${CMAKE_CURRENT_BINARY_DIR}/${DESKTOP_FILE}
+    )
+
+    # Install the generated desktop file
+    install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${DESKTOP_FILE}
+            DESTINATION ${CMAKE_INSTALL_DATADIR}/applications)
+
+endmacro(add_translations)
+
+# Generates a translations template (.pot file) by extracting all translatable
+# strings from source files, including .desktop files. Requires a list of paths to
+# scan for translatable sources, relative to the root of the source tree
+#
+# Arguments:
+# - DOMAIN: translation domain, generally the name of the app or project.
+#           It will determine the name of the generated .pot file
+# - DESKTOP_FILE: the name portion of the desktop file to merge translations into
+# - COPYRIGHT_HOLDER: the copyright holder arg to pass to xgettext
+macro(add_translations_template DOMAIN DESKTOP_FILE COPYRIGHT_HOLDER)
+    add_custom_target(pot ALL COMMENT "Generating translation template...")
+    find_program(XGETTEXT_EXECUTABLE xgettext)
+    set(PROJECT ${DOMAIN})
+    set(POT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/${DOMAIN}.pot)
+
+    # Init the list which will hold all the sources across all dirs
+    set(SOURCES "")
+
+    # Add each directory's sources to the overall sources list
+    foreach(FILES_INPUT ${ARGN})
+        set(DIR ${CMAKE_SOURCE_DIR}/${FILES_INPUT})
+        file(GLOB_RECURSE DIR_SOURCES
+            RELATIVE ${CMAKE_SOURCE_DIR}/po
+            ${DIR}/*.c ${DIR}/*.cc ${DIR}/*.cpp ${DIR}/*.cxx
+            ${DIR}/*.h ${DIR}/*.vala ${DIR}/*.qml ${DIR}/*.js)
+        set(SOURCES ${SOURCES} ${DIR_SOURCES})
+    endforeach()
+
+    # Generate the translations template (.pot file)
+    add_custom_command(TARGET pot
+        COMMAND ${INTLTOOL_EXTRACT} --update --type=gettext/ini
+            --srcdir=${CMAKE_SOURCE_DIR} ${DESKTOP_FILE}.in.in
+        COMMAND ${XGETTEXT_EXECUTABLE} -o ${POT_FILE}
+            -d ${DOMAIN}
+            -D ${CMAKE_CURRENT_SOURCE_DIR}
+            -D ${CMAKE_CURRENT_BINARY_DIR}
+            --from-code=UTF-8
+            --c++ --qt --add-comments=TRANSLATORS
+            --keyword=tr --keyword=tr:1,2 --keyword=N_
+            --package-name='${PROJECT}'
+            --copyright-holder='${COPYRIGHT_HOLDER}'
+            ${SOURCES} ${DESKTOP_FILE}.in.in.h
+        COMMAND ${CMAKE_COMMAND} -E copy ${POT_FILE} ${CMAKE_CURRENT_SOURCE_DIR})
+
+endmacro(add_translations_template)

=== modified file 'po/CMakeLists.txt'
--- po/CMakeLists.txt	2014-08-13 06:41:37 +0000
+++ po/CMakeLists.txt	2014-10-13 20:01:49 +0000
@@ -1,30 +1,3 @@
-include(FindGettext)
-find_program(GETTEXT_XGETTEXT_EXECUTABLE xgettext)
-
-set(DOMAIN ${PROJECT_NAME})
-set(POT_FILE ${DOMAIN}.pot)
-file(GLOB PO_FILES *.po)
-
-add_custom_target(${POT_FILE} ALL
-    COMMENT "Generating translation template..."
-    COMMAND ${INTLTOOL_EXTRACT} --update --type=gettext/ini
-        --srcdir=${CMAKE_SOURCE_DIR} ${DESKTOP_FILE}.in.in
-    COMMAND ${GETTEXT_XGETTEXT_EXECUTABLE} -o ${POT_FILE}
-        -D ${CMAKE_CURRENT_SOURCE_DIR}
-        -D ${CMAKE_CURRENT_BINARY_DIR}
-        --from-code=UTF-8
-        --c++ --qt --add-comments=TRANSLATORS
-        --keyword=tr --keyword=tr:1,2 --keyword=N_
-        --package-name='${PROJECT}'
-        --copyright-holder='Canonical Ltd.'
-        ${I18N_SRC_FILES}
-    COMMAND ${CMAKE_COMMAND} -E copy ${POT_FILE} ${CMAKE_CURRENT_SOURCE_DIR})
-
-foreach(PO_FILE ${PO_FILES})
-    get_filename_component(LANG ${PO_FILE} NAME_WE)
-    gettext_process_po_files(${LANG} ALL PO_FILES ${PO_FILE})
-    set(INSTALL_DIR ${CMAKE_INSTALL_LOCALEDIR}/${LANG}/LC_MESSAGES)
-    install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${LANG}.gmo
-            DESTINATION ${INSTALL_DIR}
-            RENAME ${DOMAIN}.mo)
-endforeach(PO_FILE)
+include(Translations)
+add_translations("${GETTEXT_PACKAGE}" "${DESKTOP_FILE}")
+add_translations_template("${GETTEXT_PACKAGE}" "${DESKTOP_FILE}" "Canonical Ltd." app backend)