Merge lp:~codygarver/maya/fix-schema-cmake into lp:~elementary-apps/maya/trunk

[Cody Garver]

Correctly installs gschema.xml file

[Cody Garver (codygarver)]

review: Approve

=== modified file 'CMakeLists.txt'
--- CMakeLists.txt	2011-08-31 20:40:35 +0000
+++ CMakeLists.txt	2011-09-21 02:02:23 +0000
@@ -14,6 +14,8 @@
 set (VERSION "0.2.0")
 set (VERSION_INFO "Release")
 
+list (APPEND CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
+
 #
 # Niceties
 #
@@ -123,32 +125,6 @@
 #
 # GSettings Schema
 #
-SET (MAYA_SCHEMAS "org.elementary.Maya.gschema.xml")
-
-# Have an option to not install the schema into where GLib is
-option (GSETTINGS_LOCALINSTALL "Install GSettings Schemas locally instead of to the GLib prefix" OFF)
-if (GSETTINGS_LOCALINSTALL)
-    SET (GSETTINGS_DIR "${CMAKE_INSTALL_PREFIX}/share/glib-2.0/schemas/")
-else (GSETTINGS_LOCALINSTALL)
-    execute_process (COMMAND ${PKG_CONFIG_EXECUTABLE} glib-2.0 --variable prefix OUTPUT_VARIABLE _glib_prefix OUTPUT_STRIP_TRAILING_WHITESPACE)
-    SET (GSETTINGS_DIR "${_glib_prefix}/share/glib-2.0/schemas/")
-endif (GSETTINGS_LOCALINSTALL)
-
-# Run the validator and error if it fails
-execute_process (COMMAND ${PKG_CONFIG_EXECUTABLE} gio-2.0 --variable glib_compile_schemas  OUTPUT_VARIABLE _glib_comple_schemas OUTPUT_STRIP_TRAILING_WHITESPACE)
-execute_process (COMMAND ${_glib_comple_schemas} --dry-run --schema-file=${CMAKE_CURRENT_SOURCE_DIR}/${MAYA_SCHEMAS} ERROR_VARIABLE _schemas_invalid OUTPUT_STRIP_TRAILING_WHITESPACE)
-
-if (_schemas_invalid)
-  message (SEND_ERROR "Schema validation error: ${_schemas_invalid}")
-endif (_schemas_invalid)
-
-# Actually install and recomple schemas
-message (STATUS "GSettings schemas will be installed into ${GSETTINGS_DIR}")
-install (FILES ${MAYA_SCHEMAS} DESTINATION ${GSETTINGS_DIR} OPTIONAL)
-install (CODE "message (STATUS \"Compiling GSettings schemas\")")
-install (CODE "execute_process (COMMAND ${_glib_comple_schemas} ${GSETTINGS_DIR})")
-
-# Update desktop database
-install (CODE "message (STATUS \"Updating desktop database\")")
-install (CODE "execute_process (COMMAND update-desktop-database)")
+include(GSettings)
+add_schema("org.elementary.Maya.gschema.xml")
 

=== added file 'cmake/GSettings.cmake'
--- cmake/GSettings.cmake	1970-01-01 00:00:00 +0000
+++ cmake/GSettings.cmake	2011-09-21 02:02:23 +0000
@@ -0,0 +1,42 @@
+# GSettings.cmake, CMake macros written for Marlin, feel free to re-use them.
+
+option (GSETTINGS_LOCALINSTALL "Install GSettings Schemas locally instead of to the GLib prefix" ON)
+
+option (GSETTINGS_COMPILE "Compile GSettings Schemas after installation" ${GSETTINGS_LOCALINSTALL})
+
+if(GSETTINGS_LOCALINSTALL)
+    message(STATUS "GSettings schemas will be installed locally.")
+endif()
+
+if(GSETTINGS_COMPILE)
+    message(STATUS "GSettings shemas will be compiled.")
+endif()
+
+macro(add_schema SCHEMA_NAME)
+
+    set(PKG_CONFIG_EXECUTABLE pkg-config)
+    # Have an option to not install the schema into where GLib is
+    if (GSETTINGS_LOCALINSTALL)
+        SET (GSETTINGS_DIR "${CMAKE_INSTALL_PREFIX}/share/glib-2.0/schemas/")
+    else (GSETTINGS_LOCALINSTALL)
+        execute_process (COMMAND ${PKG_CONFIG_EXECUTABLE} glib-2.0 --variable prefix OUTPUT_VARIABLE _glib_prefix OUTPUT_STRIP_TRAILING_WHITESPACE)
+        SET (GSETTINGS_DIR "${_glib_prefix}/share/glib-2.0/schemas/")
+    endif (GSETTINGS_LOCALINSTALL)
+
+    # Run the validator and error if it fails
+    execute_process (COMMAND ${PKG_CONFIG_EXECUTABLE} gio-2.0 --variable glib_compile_schemas  OUTPUT_VARIABLE _glib_comple_schemas OUTPUT_STRIP_TRAILING_WHITESPACE)
+    execute_process (COMMAND ${_glib_comple_schemas} --dry-run --schema-file=${CMAKE_CURRENT_SOURCE_DIR}/${SCHEMA_NAME} ERROR_VARIABLE _schemas_invalid OUTPUT_STRIP_TRAILING_WHITESPACE)
+
+    if (_schemas_invalid)
+      message (SEND_ERROR "Schema validation error: ${_schemas_invalid}")
+    endif (_schemas_invalid)
+
+    # Actually install and recomple schemas
+    message (STATUS "GSettings schemas will be installed into ${GSETTINGS_DIR}")
+    install (FILES ${CMAKE_CURRENT_SOURCE_DIR}/${SCHEMA_NAME} DESTINATION ${GSETTINGS_DIR} OPTIONAL)
+
+    if (GSETTINGS_COMPILE)
+        install (CODE "message (STATUS \"Compiling GSettings schemas\")")
+        install (CODE "execute_process (COMMAND ${_glib_comple_schemas} ${GSETTINGS_DIR})")
+    endif ()
+endmacro()