Merge lp:~charlesk/cmake-extras/formatcode into lp:cmake-extras

[Charles Kerr]

Add optional `formatcode' test and rule for comparing code to, and reformatting code to, a style guide standard.

Add optional `formatcode' test and rule. For the specified sources, the test checks to see if they match some style guide and 'make formatcode' reformats them.

Standalone projects will specify their own style options, but projects following a 'house style' -- such as the unity-api format -- can use common files installed in cmake/Modules/formatcode/.

This MP includes common files for the unity-api team, taken from michi's astyle and clang-foramt files

[Pete Woods (pete-woods)]

Sorry for the long delay. I pushed a branch (lp:~pete-woods/cmake-extras/formatcode-changes) that includes the changes I'd recommend, which are:
1) Include the parse arguments module in the main Format cmake file.
2) Use sed, rather than dos2unix, as this is installed by default on Ubuntu.

FYI, I used the following small project for testing with:
http://people.canonical.com/~pete/formatcode-test.tar.gz

review: Needs Fixing

[Pete Woods (pete-woods)]

Thanks for the fixes! :)

review: Approve

[Michi Henning (michihenning)]

Superb, thank you!

Minor niggles:

+ if(atyle AND astyle_config)

should be

+ if(astyle AND astyle_config)

+# --pad-oper

We can enable this now, the padding for rvalue references was fixed in astyle 2.05.

One thing I'd like to be able to do is to sit in vi and occasionally run the current file through the formatter by typing

1G!Gformatcode

Any chance we could add a way to do this (assuming that I add the relevant dir to my path, of course)?

review: Needs Fixing

[Michi Henning (michihenning)]

Also, we probably should add

SortIncludes: false

to the clang config. Otherwise, it sorts all #includes into alphabetical order, which conflicts with our style guide. (This must have been added with 3.6 or later; it didn't use to do this.)

[Michi Henning (michihenning)]

And I just stumbled across this one in the astyle doc:

--lineend=linux

I haven't tried whether this works as you'd think it does. But, if it does, we could ditch the line-ending re-writing with sed altogether.

[lp:~charlesk/cmake-extras/formatcode]

45. By Charles Kerr on 2016-04-22

tyop fix: s/atyle/astyle/

46. By Charles Kerr on 2016-04-22

in unity-api's astyle config, enable --pad-oper since it's been fixed in astyle 2.05

47. By Charles Kerr on 2016-04-22

in unity-api's clang-format, add 'SortIncludes: false'

[Charles Kerr (charlesk)]

> + if(astyle AND astyle_config)

Good catch! Fixed r45

> +# --pad-oper

Enabled r46

> SortIncludes: false

Added r47

> --lineend=linux

Looks like this should do what we want. I'll test this out tomorrow and, depending how it goes, either update the patch or add a followup comment here.

> 1G!Gformatcode

I would use this too. I don't have that in this MR but it might make a nice Friday project.

[lp:~charlesk/cmake-extras/formatcode]

48. By Charles Kerr on 2016-04-23

use astyle's linux linefeed option instead of reformatting with sed

49. By Charles Kerr on 2016-04-23

initial formatcode filter file. doesn't do anything yet.

50. By Charles Kerr on 2016-04-23

try adapting the formatcode filter from unity-scopes-api

51. By Charles Kerr on 2016-04-23

fix formatting errors

52. By Charles Kerr on 2016-04-23

when installing our modules, preserve the source files' permissions. needed for the formatcode.in script.

53. By Charles Kerr on 2016-04-23

updat the 'make formatcode' rule and formatcode test to use the new filter

[Charles Kerr (charlesk)]

I had a couple of hours' layover today with no internet access, so I decided to go ahead and do this...

michi, as of r53 there's a ~/build/formatcode filter script based on the unity-scopes-api/trunk/tools/formatcode.in.

[Michi Henning (michihenning)]

Bloody awesome, thank you so much!

review: Approve

=== modified file 'CMakeLists.txt'
--- CMakeLists.txt	2015-06-19 09:04:54 +0000
+++ CMakeLists.txt	2016-04-23 15:31:47 +0000
@@ -1,13 +1,8 @@
 project(cmake-extras)
 cmake_minimum_required(VERSION 2.8.9)
 
-file(
-  GLOB_RECURSE SRC_FILES
-  "src/*.cmake"
-  "src/*.in"
-)
-
 install(
-  FILES ${SRC_FILES}
+  DIRECTORY "src/"
   DESTINATION "${CMAKE_ROOT}/Modules/"
+  USE_SOURCE_PERMISSIONS 
 )

=== added file 'src/FormatCode.cmake'
--- src/FormatCode.cmake	1970-01-01 00:00:00 +0000
+++ src/FormatCode.cmake	2016-04-23 15:31:47 +0000
@@ -0,0 +1,238 @@
+# .rst:
+# FormatCode
+# ----------
+#
+# Helpers to reformat source or test that it follows a style guide.
+# Supports astyle and clang-format.
+#
+# The ``ADD_FORMATCODE_TARGET'' function adds a rule
+# to reformat the specified sources into the desired style::
+#
+#    add_formatcode_target(
+#        sources
+#        [STYLE_NAME <name>]
+#        [ASTYLE_CONFIG <path>]
+#        [CFORMAT_CONFIG <path>]
+#    )
+#
+# If the ``STYLE_NAME`` argument is used, formatcode first looks for shared
+# style files installed in the FormatCode module's formatcode/ directory.
+#
+# Otherwise it looks in ${CMAKE_SOURCE_DIR} and ${CMAKE_SOURCE_DIR}/data/
+# for the ``ASTYLE_CONFIG`` and ``CFORMAT_CONFIG`` files.
+#
+# The ``ADD_FORMATCODE_TEST'' function takes the same arguments as
+# ``ADD_FORMATCODE_TARGET'' and adds a test to see if the specified
+# sources follow the desired style::
+#
+#    add_formatcode_test(
+#        sources
+#        [STYLE_NAME <name>]
+#        [ASTYLE_CONFIG <path>]
+#        [CFORMAT_CONFIG <path>]
+#    )
+#
+#   Example use:
+#
+#   In CMakeLists.txt:
+#
+#     file(GLOB_RECURSE MY_SOURCES src/*.cpp src/*.cxx src/*.cc src/*.h)
+#     include(FormatCode)
+#     add_formatcode_target(${MY_SOURCES} STYLE_NAME unity-api)
+#
+#   In tests/CMakeLists.txt:
+#
+#     add_formatcode_test(${MY_SOURCES} STYLE_NAME unity-api)
+#
+
+#=============================================================================
+# Copyright 2016 Canonical Ltd
+#
+# This file may be licensed under the terms of the
+# GNU Lesser General Public License Version 3 (the ``LGPL''),
+# or (at your option) any later version.
+#
+# Software distributed under the License is distributed
+# on an ``AS IS'' basis, WITHOUT WARRANTY OF ANY KIND, either
+# express or implied. See the LGPL for the specific language
+# governing rights and limitations.
+#
+# You should have received a copy of the LGPL along with this
+# program. If not, go to http://www.gnu.org/licenses/lgpl.html
+# or write to the Free Software Foundation, Inc.,
+# 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
+#=============================================================================
+
+include(CMakeParseArguments)
+
+set(FC_CMAKE_MODULE_DIR ${CMAKE_CURRENT_LIST_DIR}/formatcode)
+
+function(_fc_find_style_files FC_STYLE_NAME FC_ASTYLE_CONFIG FC_CFORMAT_CONFIG)
+
+    message(STATUS "checking for astyle or clang-format")
+
+    set(style_search_path
+        ${CMAKE_SOURCE_DIR}
+        ${CMAKE_SOURCE_DIR}/data
+        ${FC_CMAKE_MODULE_DIR}
+    )
+    
+    if(FC_STYLE_NAME)
+        set(filename ${FC_STYLE_NAME}.astyle)
+        find_file(astyle_tmp ${filename} PATHS ${style_search_path})
+        set(filename ${FC_STYLE_NAME}.clang-format)
+        find_file(cformat_tmp ${filename} PATHS ${style_search_path})
+    endif()
+
+    if(FC_ASTYLE_CONFIG AND NOT astyle_tmp)
+        if(EXISTS ${FC_ASTYLE_CONFIG})
+            set(astyle_tmp ${FC_ASTYLE_CONFIG})
+        else()
+            find_file(astyle_tmp
+                NAMES ${FC_ASTYLE_CONFIG} astyle-config
+                PATHS ${style_search_path}
+            )
+        endif()
+    endif()
+
+    if(FC_CFORMAT_CONFIG AND NOT cformat_tmp)
+        if(EXISTS ${FC_CFORMAT_CONFIG})
+            set(cformat_tmp ${FC_CFORMAT_CONFIG})
+        else()
+            find_file(cformat_tmp
+                NAMES ${FC_CFORMAT_CONFIG} cformat-config
+                PATHS ${style_search_path}
+            )
+        endif()
+    endif()
+
+    # set retvals
+
+    if(astyle_tmp)
+        message(STATUS "  found ${astyle_tmp}")
+        set(FC_ASTYLE_CONFIG ${astyle_tmp} PARENT_SCOPE)
+    else()
+        unset(FC_ASTYLE_CONFIG PARENT_SCOPE)
+    endif()
+
+    if(cformat_tmp)
+        message(STATUS "  found ${cformat_tmp}")
+        set(FC_CFORMAT_CONFIG ${cformat_tmp} PARENT_SCOPE)
+    else()
+        unset(FC_CFORMAT_CONFIG PARENT_SCOPE)
+    endif()
+
+endfunction()
+
+function(_fc_find_apps FC_ASTYLE_CONFIG FC_CFORMAT_CONFIG)
+
+    if(EXISTS ${FC_ASTYLE_CONFIG})
+        # find astyle...
+        find_program(ASTYLE NAMES astyle)
+        if(NOT ASTYLE)
+            message(WARNING "found astyle config file, but not astyle")
+        endif()
+    endif()
+
+    if(EXISTS ${FC_CFORMAT_CONFIG})
+        # find clang-format executable...
+        find_program(CFORMAT NAMES clang-format clang-format-3.8 clang-format-3.7 clang-format-3.6 clang-format-3.5)
+        if(NOT CFORMAT)
+            message(WARNING "found clang-format style file, but not clang-format")
+        endif()
+    endif()
+
+    # set retvals
+
+    if(ASTYLE)
+        message(STATUS "  found ${ASTYLE}")
+        set(FC_ASTYLE ${ASTYLE} PARENT_SCOPE)
+    else()
+        unset(FC_ASTYLE PARENT_SCOPE)
+    endif()
+
+    if(CFORMAT)
+        message(STATUS "  found ${CFORMAT}")
+        set(FC_CFORMAT ${CFORMAT} PARENT_SCOPE)
+    else()
+        unset(FC_CFORMAT PARENT_SCOPE)
+    endif()
+
+endfunction()
+
+# cmake doesn't have a mktemp func, so roll a simple one
+function(_fc_mktemp in out)
+    set(_counter 1)
+    while(EXISTS ${in}.${_counter})
+        math(EXPR _counter "${_counter} + 1")
+    endwhile()
+    set(${out} "${in}.${_counter}" PARENT_SCOPE)
+endfunction()
+
+# clang-format has a goofy wart, it doesn't let you pass in an arbitrary
+# style file. But, you CAN pass style options on the command line with
+# --style="{foo: bar, mum: baz}" ... so let's read the style file in
+# and bang it into a --style string
+function(_fc_get_cformat_style cformat_style_string filename)
+    file(READ ${filename} contents)
+    STRING(REGEX REPLACE ";" "\\\\;" contents "${contents}")
+    STRING(REGEX REPLACE "\n" ";" contents "${contents}")
+    set(style)
+    foreach(LINE IN LISTS contents)
+        string(STRIP "${LINE}" LINE)
+        if (LINE MATCHES ".*:.*")
+            set(style "${style}${LINE}, ")
+        endif()
+    endforeach(LINE)
+    STRING(LENGTH "${style}" len)
+    if(${len} GREATER 2) # trim the trailing ", "
+        MATH(EXPR len "${len}-2")
+        STRING(SUBSTRING "${style}" 0 ${len} style)
+    endif()
+    # set retval
+    set(${cformat_style_string} "{${style}}" PARENT_SCOPE)
+endfunction()
+
+
+# add_custom_target() and add_test() can take a cmake file argument but not a
+# function name argument, so we generate cmake files to call
+# formatcode_format_files() or formatcode_test_files() with the right FC_* args
+function(_fc_configure_new_cmake_file filename template_name)
+
+    # parse the args
+    set(options)
+    set(oneValueArgs STYLE_NAME ASTYLE_CONFIG CFORMAT_CONFIG)
+    set(multiValueArgs)
+    cmake_parse_arguments(FC "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+    set(FC_SOURCES "${FC_UNPARSED_ARGUMENTS}")
+
+    # use the args to find the right formatters and config files
+    _fc_find_style_files("${FC_STYLE_NAME}" "${FC_ASTYLE_CONFIG}" "${FC_CFORMAT_CONFIG}")
+    _fc_find_apps("${FC_ASTYLE_CONFIG}" "${FC_CFORMAT_CONFIG}")
+
+    # build the filter
+    set(FC_COMMAND ${CMAKE_BINARY_DIR}/formatcode)
+    _fc_get_cformat_style(FC_CFORMAT_STYLE "${FC_CFORMAT_CONFIG}")
+    configure_file(${FC_CMAKE_MODULE_DIR}/formatcode.in ${FC_COMMAND} @ONLY)
+
+    # build the config file
+    _fc_mktemp(${CMAKE_BINARY_DIR}/${template_name} TMPFILE)
+    set(TMPFILE ${TMPFILE}.cmake)
+    configure_file(${FC_CMAKE_MODULE_DIR}/${template_name}.cmake.in ${TMPFILE} @ONLY)
+
+    # set the retval, the filename of the generated file
+    set(${filename} ${TMPFILE} PARENT_SCOPE)
+endfunction()
+
+# add a 'make formatcode' target to reformat the source files
+function(add_formatcode_target)
+    _fc_configure_new_cmake_file(cmake_file "formatcode_format" ${ARGN})
+    add_custom_target(formatcode COMMAND ${CMAKE_COMMAND} -P ${cmake_file} DEPENDS ${FC_SOURCES})
+endfunction()
+
+# add a 'formatcode' test to confirm the source files follow the style guide
+function(add_formatcode_test)
+    _fc_configure_new_cmake_file(cmake_file "formatcode_test" ${ARGN})
+    add_test(NAME formatcode COMMAND ${CMAKE_COMMAND} -P ${cmake_file})
+endfunction()
+

=== added directory 'src/formatcode'
=== added file 'src/formatcode/formatcode.in'
--- src/formatcode/formatcode.in	1970-01-01 00:00:00 +0000
+++ src/formatcode/formatcode.in	2016-04-23 15:31:47 +0000
@@ -0,0 +1,61 @@
+#!/bin/sh
+
+# Copyright (C) 2013-2016 Canonical Ltd
+#
+# This program is free software: you can redistribute it and/or modify
+# it under the terms of the GNU Lesser General Public License version 3 as
+# published by the Free Software Foundation.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU Lesser General Public License for more details.
+#
+# You should have received a copy of the GNU Lesser General Public License
+# along with this program.  If not, see <http://www.gnu.org/licenses/>.
+#
+# Authors:
+#   Michi Henning <[e-mail]>
+#   Charles Kerr <[e-mail]>
+
+# Simple script to format files with astyle, followed by clang-format (which
+# undoes some damage that's done by astyle, without wiping out astyle edits we want
+# to happen).
+#
+# usage: formatcode [FILE]...
+#
+# If no arguments are provided, we format stdin and write to stdout.
+
+astyle="@FC_ASTYLE@"
+astyle_config="@FC_ASTYLE_CONFIG@"
+cformat="@FC_CFORMAT@"
+cformat_style="@FC_CFORMAT_STYLE@"
+
+# if no arguments were provided, read stdin and write stdout.
+files="$@"
+[ $# -eq 0 ] && {
+    tmpdir=`mktemp -d`
+    tmp=`mktemp -p $tmpdir`
+    cat >$tmp
+    files="$tmp"
+}
+
+# maybe run astyle
+[ -n "$astyle" -a -n "$astyle_config" ] && {
+    "$astyle" -q --options="$astyle_config" --lineend=linux -n "$files"
+}
+
+# maybe run clang-format
+[ -n "$cformat" -a -n "$cformat_style" ] && {
+    "$cformat" -i -style="$cformat_style" "$files"
+}
+
+# if no arguments were provided, read stdin and write stdout.
+[ $# -eq 0 ] && {
+    cat "$tmp"
+    rm -rf $tmpdir
+}
+
+exit $?
+
+

=== added file 'src/formatcode/formatcode_common.cmake'
--- src/formatcode/formatcode_common.cmake	1970-01-01 00:00:00 +0000
+++ src/formatcode/formatcode_common.cmake	2016-04-23 15:31:47 +0000
@@ -0,0 +1,79 @@
+#=============================================================================
+# Copyright 2016 Canonical Ltd
+#
+# This file may be licensed under the terms of the
+# GNU Lesser General Public License Version 3 (the ``LGPL''),
+# or (at your option) any later version.
+#
+# Software distributed under the License is distributed
+# on an ``AS IS'' basis, WITHOUT WARRANTY OF ANY KIND, either
+# express or implied. See the LGPL for the specific language
+# governing rights and limitations.
+#
+# You should have received a copy of the LGPL along with this
+# program. If not, go to http://www.gnu.org/licenses/lgpl.html
+# or write to the Free Software Foundation, Inc.,
+# 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
+#=============================================================================
+
+# formatting funcs
+
+function(formatcode_format_file fc_command filename)
+    execute_process(COMMAND ${fc_command} ${filename})
+endfunction()
+
+function(formatcode_format_files fc_command filenames)
+    foreach(filename IN LISTS filenames)
+        formatcode_format_file("${fc_command}" "${filename}")
+    endforeach(filename)
+endfunction()
+
+# testing funcs
+
+set(FORMATCODE_TEST_DIR ${CMAKE_BINARY_DIR}/formatted)
+
+function(formatcode_test_file success fc_command filename)
+
+    # copy the file into a relative path underneath $build/formatted/
+    # so that, if the test fails, we can leave the formatted copy behind
+    # as a breadcrumb without clutting any other directories
+    file(RELATIVE_PATH rel ${CMAKE_SOURCE_DIR} ${filename})
+    set(tmpfile ${FORMATCODE_TEST_DIR}/${rel})
+    get_filename_component(base ${tmpfile} NAME)
+    file(MAKE_DIRECTORY base)
+    file(REMOVE ${tmpfile})
+    file(READ ${filename} input)
+    file(WRITE ${tmpfile} "${input}")
+
+    # format the file
+    formatcode_format_file("${fc_command}" ${tmpfile})
+
+    # if the format changed, then $filename didn't match the style guide
+    string(MD5 md5in "${input}")
+    file(MD5 ${tmpfile} md5out)
+    if(md5in STREQUAL md5out)
+        file(REMOVE ${tmpfile})
+        set(${success} TRUE PARENT_SCOPE)
+    else()
+        message(STATUS "leaving formatted copy in ${tmpfile}")
+        set(${success} FALSE PARENT_SCOPE)
+    endif()
+
+endfunction()
+
+function(formatcode_test_files fc_command filenames)
+    set(error_count 0)
+    foreach(filename IN LISTS filenames)
+        formatcode_test_file(success "${fc_command}" "${filename}")
+        if(NOT success)
+            MATH(EXPR error_count "${error_count}+1")
+        endif()
+    endforeach(filename)
+    if(error_count)
+        message(FATAL_ERROR "formatcode test failed in ${error_count} files")
+    else()
+        # if nothing failed, clean up the test directory
+        file(REMOVE_RECURSE ${FORMATCODE_TEST_DIR})
+    endif()
+endfunction()
+

=== added file 'src/formatcode/formatcode_format.cmake.in'
--- src/formatcode/formatcode_format.cmake.in	1970-01-01 00:00:00 +0000
+++ src/formatcode/formatcode_format.cmake.in	2016-04-23 15:31:47 +0000
@@ -0,0 +1,31 @@
+#=============================================================================
+# Copyright 2016 Canonical Ltd
+#
+# This file may be licensed under the terms of the
+# GNU Lesser General Public License Version 3 (the ``LGPL''),
+# or (at your option) any later version.
+#
+# Software distributed under the License is distributed
+# on an ``AS IS'' basis, WITHOUT WARRANTY OF ANY KIND, either
+# express or implied. See the LGPL for the specific language
+# governing rights and limitations.
+#
+# You should have received a copy of the LGPL along with this
+# program. If not, go to http://www.gnu.org/licenses/lgpl.html
+# or write to the Free Software Foundation, Inc.,
+# 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
+#=============================================================================
+
+set(CMAKE_BINARY_DIR @CMAKE_BINARY_DIR@)
+set(CMAKE_SOURCE_DIR @CMAKE_SOURCE_DIR@)
+
+set(FC_COMMAND @FC_COMMAND@)
+set(FC_SOURCES @FC_SOURCES@)
+
+include(@FC_CMAKE_MODULE_DIR@/formatcode_common.cmake)
+
+formatcode_format_files(
+    "${FC_COMMAND}"
+    "${FC_SOURCES}"
+)
+

=== added file 'src/formatcode/formatcode_test.cmake.in'
--- src/formatcode/formatcode_test.cmake.in	1970-01-01 00:00:00 +0000
+++ src/formatcode/formatcode_test.cmake.in	2016-04-23 15:31:47 +0000
@@ -0,0 +1,31 @@
+#=============================================================================
+# Copyright 2016 Canonical Ltd
+#
+# This file may be licensed under the terms of the
+# GNU Lesser General Public License Version 3 (the ``LGPL''),
+# or (at your option) any later version.
+#
+# Software distributed under the License is distributed
+# on an ``AS IS'' basis, WITHOUT WARRANTY OF ANY KIND, either
+# express or implied. See the LGPL for the specific language
+# governing rights and limitations.
+#
+# You should have received a copy of the LGPL along with this
+# program. If not, go to http://www.gnu.org/licenses/lgpl.html
+# or write to the Free Software Foundation, Inc.,
+# 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
+#=============================================================================
+
+set(CMAKE_BINARY_DIR @CMAKE_BINARY_DIR@)
+set(CMAKE_SOURCE_DIR @CMAKE_SOURCE_DIR@)
+
+set(FC_COMMAND @FC_COMMAND@)
+set(FC_SOURCES @FC_SOURCES@)
+
+include(@FC_CMAKE_MODULE_DIR@/formatcode_common.cmake)
+
+formatcode_test_files(
+    "${FC_COMMAND}"
+    "${FC_SOURCES}"
+)
+

=== added file 'src/formatcode/unity-api.astyle'
--- src/formatcode/unity-api.astyle	1970-01-01 00:00:00 +0000
+++ src/formatcode/unity-api.astyle	2016-04-23 15:31:47 +0000
@@ -0,0 +1,30 @@
+# Options for formatting code with astyle.
+#
+# This helps to make code match the style guide.
+# 
+# Use like this:
+# 
+#     astyle --options=astyle-config mfile.h myfile.cpp
+# 
+# Occasionally, astyle does something silly (particularly with lambdas), so it's
+# still necessary to scan the changes for things that are wrong.
+# But, for most files, it does a good job.
+# 
+# Please consider using this before checking code in for review. Code reviews shouldn't
+# have to deal with layout issues, they are just a distraction. It's better to be able
+# to focus on semantics in a code review, with style issues out of the way.
+
+--formatted
+--style=allman
+--min-conditional-indent=2
+--indent-switches
+--max-instatement-indent=120
+--pad-header
+--align-pointer=type
+--align-reference=type
+--add-brackets
+--convert-tabs
+--close-templates
+--max-code-length=120
+--pad-oper
+

=== added file 'src/formatcode/unity-api.clang-format'
--- src/formatcode/unity-api.clang-format	1970-01-01 00:00:00 +0000
+++ src/formatcode/unity-api.clang-format	2016-04-23 15:31:47 +0000
@@ -0,0 +1,49 @@
+---
+AccessModifierOffset: -4
+AlignEscapedNewlinesLeft: true
+AlignTrailingComments: true
+AllowAllParametersOfDeclarationOnNextLine: true
+AllowShortFunctionsOnASingleLine: false
+AllowShortIfStatementsOnASingleLine: false
+AllowShortLoopsOnASingleLine: false
+AlwaysBreakBeforeMultilineStrings: true
+AlwaysBreakTemplateDeclarations: true
+BinPackParameters: false
+BreakBeforeBinaryOperators: false
+BreakBeforeBraces: Allman
+BreakBeforeTernaryOperators: false
+BreakConstructorInitializersBeforeComma: true
+ColumnLimit:     120
+ConstructorInitializerAllOnOneLineOrOnePerLine: false
+ConstructorInitializerIndentWidth: 4
+ContinuationIndentWidth: 4
+Cpp11BracedListStyle: true
+DerivePointerBinding: true
+ExperimentalAutoDetectBinPacking: false
+IndentCaseLabels: true
+IndentFunctionDeclarationAfterType: true
+IndentWidth:     4
+Language:        Cpp
+MaxEmptyLinesToKeep: 1
+NamespaceIndentation: None
+ObjCSpaceBeforeProtocolList: false
+PenaltyBreakBeforeFirstCallParameter: 1
+PenaltyBreakComment: 60
+PenaltyBreakFirstLessLess: 120
+PenaltyBreakString: 1000
+PenaltyExcessCharacter: 1000000
+PenaltyReturnTypeOnItsOwnLine: 200
+PointerBindsToType: true
+SortIncludes: false
+SpaceBeforeAssignmentOperators: true
+SpaceBeforeParens: ControlStatements
+SpaceInEmptyParentheses: false
+SpacesBeforeTrailingComments: 2
+SpacesInAngles:  false
+SpacesInCStyleCastParentheses: false
+SpacesInParentheses: false
+Standard:        Cpp11
+TabWidth:        8
+UseTab:          Never
+...
+