Merge lp:~allanlesage/overlay-scrollbar/TDD into lp:overlay-scrollbar

[Allan LeSage]

Adding gcov targets to autotools build for code-coverage reporting. For more information, see this blog post: http://qualityhour.wordpress.com/2012/01/29/test-coverage-tutorial-for-cc-autotools-projects/ . To compile with coverage tooling, ./autogen.sh --enable-gcov, then make coverage-html . Note that you'll need lcov to autoconf. Also note that you'll get an error on make if you have no tests, as there are no coverage artifacts to generate the html report. For review, please pay special attention to flags added in the project's makefiles.

[jenkins (martin-mrazik+qa)]

PASSED: Continuous integration, rev:338
http://s-jenkins:8080/job/ayatana-scrollbar-ci/2/

review: Approve (continuous-integration)

[PS Jenkins bot (ps-jenkins)]

FAILED: Continuous integration, rev:338
http://jenkins.qa.ubuntu.com/job/ayatana-scrollbar-ci/8/
Executed test runs:
    FAILURE: http://jenkins.qa.ubuntu.com/job/ayatana-scrollbar-ci/./build=pbuilder,distribution=quantal,flavor=amd64/8/console
    FAILURE: http://jenkins.qa.ubuntu.com/job/ayatana-scrollbar-ci/./build=pbuilder,distribution=quantal,flavor=i386/8/console

review: Needs Fixing (continuous-integration)

Unmerged revisions

338. By Allan LeSage on 2012-03-28

Added gcov coverage tooling.

=== modified file 'Makefile.am'
--- Makefile.am	2011-12-07 15:26:22 +0000
+++ Makefile.am	2012-04-02 14:33:30 +0000
@@ -34,3 +34,5 @@
 
 %.md5: %
 	md5sum $< > $@
+
+include $(top_srcdir)/Makefile.am.coverage

=== added file 'Makefile.am.coverage'
--- Makefile.am.coverage	1970-01-01 00:00:00 +0000
+++ Makefile.am.coverage	2012-04-02 14:33:30 +0000
@@ -0,0 +1,48 @@
+
+# Coverage targets
+
+.PHONY: clean-gcno clean-gcda \
+	coverage-html generate-coverage-html clean-coverage-html \
+	coverage-gcovr generate-coverage-gcovr clean-coverage-gcovr
+
+clean-local: clean-gcno clean-coverage-html clean-coverage-gcovr
+
+if HAVE_GCOV
+
+clean-gcno:
+	@echo Removing old coverage instrumentation
+	-find -name '*.gcno' -print | xargs -r rm
+
+clean-gcda:
+	@echo Removing old coverage results
+	-find -name '*.gcda' -print | xargs -r rm
+  
+coverage-html: clean-gcda
+	-$(MAKE) $(AM_MAKEFLAGS) -k check
+	$(MAKE) $(AM_MAKEFLAGS) generate-coverage-html
+  
+generate-coverage-html:
+	@echo Collecting coverage data
+	$(LCOV) --directory $(top_builddir) --capture --output-file coverage.info --no-checksum --compat-libtool
+	LANG=C $(GENHTML) --prefix $(top_builddir) --output-directory coveragereport --title "Code Coverage" --legend --show-details coverage.info
+  
+clean-coverage-html: clean-gcda
+	-$(LCOV) --directory $(top_builddir) -z
+	-rm -rf coverage.info coveragereport
+
+if HAVE_GCOVR
+
+coverage-gcovr: clean-gcda
+	-$(MAKE) $(AM_MAKEFLAGS) -k check
+	$(MAKE) $(AM_MAKEFLAGS) generate-coverage-gcovr
+	
+generate-coverage-gcovr:
+	@echo Generating coverage GCOVR report
+	$(GCOVR) -x -r $(top_builddir) -o $(top_builddir)/coverage.xml
+	
+clean-coverage-gcovr: clean-gcda
+	-rm -rf $(top_builddir)/coverage.xml
+
+endif # HAVE_GCOVR
+
+endif # HAVE_GCOV

=== added file 'build/gcov.m4'
--- build/gcov.m4	1970-01-01 00:00:00 +0000
+++ build/gcov.m4	2012-04-02 14:33:30 +0000
@@ -0,0 +1,86 @@
+# Checks for existence of coverage tools:
+#  * gcov
+#  * lcov
+#  * genhtml
+#  * gcovr
+# 
+# Sets ac_cv_check_gcov to yes if tooling is present
+# and reports the executables to the variables LCOV, GCOVR and GENHTML.
+AC_DEFUN([AC_TDD_GCOV],
+[
+  AC_ARG_ENABLE(gcov,
+  AS_HELP_STRING([--enable-gcov],
+		 [enable coverage testing with gcov]),
+  [use_gcov=$enableval], [use_gcov=no])
+
+  if test "x$use_gcov" = "xyes"; then
+  # we need gcc:
+  if test "$GCC" != "yes"; then
+    AC_MSG_ERROR([GCC is required for --enable-gcov])
+  fi
+
+  # Check if ccache is being used
+  AC_CHECK_PROG(SHTOOL, shtool, shtool)
+  case `$SHTOOL path $CC` in
+    *ccache*[)] gcc_ccache=yes;;
+    *[)] gcc_ccache=no;;
+  esac
+
+  if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
+    AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
+  fi
+
+  lcov_version_list="1.6 1.7 1.8 1.9"
+  AC_CHECK_PROG(LCOV, lcov, lcov)
+  AC_CHECK_PROG(GENHTML, genhtml, genhtml)
+
+  if test "$LCOV"; then
+    AC_CACHE_CHECK([for lcov version], glib_cv_lcov_version, [
+      glib_cv_lcov_version=invalid
+      lcov_version=`$LCOV -v 2>/dev/null | $SED -e 's/^.* //'`
+      for lcov_check_version in $lcov_version_list; do
+        if test "$lcov_version" = "$lcov_check_version"; then
+          glib_cv_lcov_version="$lcov_check_version (ok)"
+        fi
+      done
+    ])
+  else
+    lcov_msg="To enable code coverage reporting you must have one of the following lcov versions installed: $lcov_version_list"
+    AC_MSG_ERROR([$lcov_msg])
+  fi
+
+  case $glib_cv_lcov_version in
+    ""|invalid[)]
+      lcov_msg="You must have one of the following versions of lcov: $lcov_version_list (found: $lcov_version)."
+      AC_MSG_ERROR([$lcov_msg])
+      LCOV="exit 0;"
+      ;;
+  esac
+
+  if test -z "$GENHTML"; then
+    AC_MSG_ERROR([Could not find genhtml from the lcov package])
+  fi
+
+  ac_cv_check_gcov=yes
+  ac_cv_check_lcov=yes
+
+  # Remove all optimization flags from CFLAGS
+  changequote({,})
+  CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
+  changequote([,])
+
+  # Add the special gcc flags
+  COVERAGE_CFLAGS="-O0 -fprofile-arcs -ftest-coverage"
+  COVERAGE_CXXFLAGS="-O0 -fprofile-arcs -ftest-coverage"	
+  COVERAGE_LDFLAGS="-lgcov"
+
+  # Check availability of gcovr
+  AC_CHECK_PROG(GCOVR, gcovr, gcovr)
+  if test -z "$GCOVR"; then
+    ac_cv_check_gcovr=no
+  else
+    ac_cv_check_gcovr=yes
+  fi
+
+fi
+]) # AC_TDD_GCOV

=== modified file 'configure.ac'
--- configure.ac	2012-03-21 13:52:39 +0000
+++ configure.ac	2012-04-02 14:33:30 +0000
@@ -154,6 +154,16 @@
 OS_LDFLAGS="\$(OS_LT_LDFLAGS) -export-symbols-regex \^[_]*\(os_\|Os\|OS_\).* -no-undefined"
 AC_SUBST(OS_LDFLAGS)
 
+# Coverage
+
+m4_include([build/gcov.m4])
+AC_TDD_GCOV
+AM_CONDITIONAL([HAVE_GCOV], [test "x$ac_cv_check_gcov" = xyes])
+AM_CONDITIONAL([HAVE_LCOV], [test "x$ac_cv_check_lcov" = xyes])
+AM_CONDITIONAL([HAVE_GCOVR], [test "x$ac_cv_check_gcovr" = xyes])
+AC_SUBST(COVERAGE_CFLAGS)
+AC_SUBST(COVERAGE_LDFLAGS)
+
 # Files
 
 AC_CONFIG_FILES([
@@ -179,6 +189,7 @@
 echo "  Tests:  ${enable_tests}"
 echo "  Debug:  ${enable_debug}"
 echo "  Prefix: ${prefix}"
+echo "  gcov:   ${use_gcov}"
 echo ""
 echo "  Compiler flags: ${CPPFLAGS} ${DEBUG_CFLAGS} ${MAINTAINER_CFLAGS}"
 echo ""

=== modified file 'os/Makefile.am'
--- os/Makefile.am	2011-10-07 00:36:53 +0000
+++ os/Makefile.am	2012-04-02 14:33:30 +0000
@@ -27,11 +27,15 @@
 
 liboverlay_scrollbar_@OS_MAJORMINOR@_la_SOURCES = $(source_c)
 
-liboverlay_scrollbar_@OS_MAJORMINOR@_la_CFLAGS = $(OS_CFLAGS)
+liboverlay_scrollbar_@OS_MAJORMINOR@_la_CFLAGS = \
+	$(OS_CFLAGS) \
+	$(COVERAGE_CFLAGS)
 
 liboverlay_scrollbar_@OS_MAJORMINOR@_la_LIBADD = $(OS_LIBADD)
 
-liboverlay_scrollbar_@OS_MAJORMINOR@_la_LDFLAGS = $(OS_LDFLAGS)
+liboverlay_scrollbar_@OS_MAJORMINOR@_la_LDFLAGS = \
+	$(OS_LDFLAGS) \
+	$(COVERAGE_CFLAGS)
 
 liboverlay_scrollbar_@OS_MAJORMINOR@_includedir = \
 	$(includedir)/overlay-scrollbar$(VER)-@OS_MAJORMINOR@/os
@@ -48,9 +52,12 @@
 os3include_HEADERS = $(osinclude_HEADERS)
 liboverlay_scrollbar3_@OS_MAJORMINOR@_la_SOURCES =  $(source_c)
 liboverlay_scrollbar3_@OS_MAJORMINOR@_la_CFLAGS = $(OS_CFLAGS) \
-  -DUSE_GTK3
+	$(COVERAGE_CFLAGS) \
+	-DUSE_GTK3
 liboverlay_scrollbar3_@OS_MAJORMINOR@_la_LIBADD = $(OS_LIBADD)
-liboverlay_scrollbar3_@OS_MAJORMINOR@_la_LDFLAGS = $(OS_LDFLAGS)
+liboverlay_scrollbar3_@OS_MAJORMINOR@_la_LDFLAGS = \
+	$(OS_LDFLAGS) \
+	$(COVERAGE_CFLAGS)
 liboverlay_scrollbar3_@OS_MAJORMINOR@_includedir = $(includedir)/overlay-scrollbar$(VER)-@OS_MAJORMINOR@/os
 liboverlay_scrollbar3_@OS_MAJORMINOR@_include_HEADERS = \
 	$(source_h) \